使用键和变量的XSLT

Question

嗨，所有这些问题都与此相关:xsl从另一个节点树获取元素值，但这次我有一个工作xslt。

我目前正在处理以下xml:

 <record>
  <leader>01877nz  a2200433o  4500</leader>
  <controlfield tag="001">1</controlfield>
        ... (more controlfields tag 002 to 010)
  <datafield tag="013" ind1=" " ind2=" ">
   <subfield code="a">formerge</subfield>
  </datafield>
          ... (more datafield tags, datafield tags are from 011 to 999)
  <datafield tag="150" ind1=" " ind2=" ">
   <subfield code="a">Borneo</subfield>
  </datafield>
          ... (more datafield tags, datafield tags are from 011 to 999)
  <datafield tag="550" ind1=" " ind2=" ">
   <subfield code="w">g</subfield>
   <subfield code="a">South East Asia</subfield>
   <subfield code="c">c_7260</subfield>
  </datafield>
       ... (more datafield tags, datafield tags are from 011 to 999)
  </record>
       ... (more records)
  <record>
       ... (more records fields)
       ... (more records fields)
  </record>
  <record>
   <leader>02462nz  a2200553o  4500</leader>
   <controlfield tag="001">2</controlfield>
         ... (more controlfields tag 002 to 010)
   <datafield tag="013" ind1=" " ind2=" ">
    <subfield code="a">formerge</subfield>
   </datafield>
   <datafield tag="035" ind1=" " ind2=" ">
    <subfield code="a">c_7260</subfield>
   </datafield>
       ... (more datafield tags, datafield tags are from 011 to 999)
   <datafield tag="151" ind1=" " ind2=" ">
    <subfield code="a">South East Asia</subfield>
   </datafield>
       ... (more datafield tags, datafield tags are from 011 to 999)
  </record>

我有以下xslt:

<?xml version="1.0" encoding="UTF-8"?>
 <xsl:stylesheet version="1.0" xmlns:marc="http://www.loc.gov/MARC21/slim"    xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"    xmlns:dc="http://purl.org/dc/elements/1.1/"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="marc">
 <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
 <xsl:key name="term" match="//datafield[@tag='151'][subfield[@code='a']]" use="." />
 <xsl:template match="//datafield[@tag='151'][subfield[@code='a']]">
  <xsl:variable name="t550a" select="//datafield[@tag='550'][subfield[@code='a']]" />
  <xsl:for-each select="key('term','$550a')">
   <xsl:value-of select="//controlfield[@tag='001']" />
  </xsl:for-each>
 </xsl:template>
 <xsl:template match="@*|node()">
  <xsl:copy>
   <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
 </xsl:template>    
</xsl:stylesheet>

这样，我创建了一个包含所有151个通过键(term)的索引。我还创建了一个变量"t550a"。通过keys函数，我将550a标记(数据字段标记="550"子字段代码="a")与term key匹配。然后得到那个键的controlfield标签001的值。我还想获得我的xml的所有节点，因此"xsl:copy"。使用我的xslt，数据字段标记151似乎被删除了。

我想进入550字段如下:

        ... (other fields omitted)
<datafield tag="550" ind1=" " ind2=" ">
 <subfield code="w">g</subfield>
 <subfield code="a">South East Asia</subfield>
 <subfield code="c">c_7260</subfield>
 <subfield code="0">2</subfield>
</datafield>
          ... (other fields omitted)
<datafield tag="550" ind1=" " ind2=" ">
 <subfield code="w">h</subfield>
 <subfield code="a">Borneo</subfield>
 <subfield code="c">c_1017</subfield>
 <subfield code="0">1</subfield>
</datafield>

因此550子字段a South East Asia将有附加的值为2的子字段0，该值基于151子字段a South East Asia的控制字段001。此外，550子字段a Borneo将有附加的子字段0，其值为1，这是基于151子字段a Borneo的控制字段001。

谁能指点我正确地做这件事?谢谢!

Answer 1

我认为你的模板匹配了错误的元素。如果您希望在"550"字段上添加子节点，则应该有一个与

匹配的模板

<xsl:template match="datafield[@tag='550'][subfield[@code='a']]">

我也会稍微调整键，因为目前键也将使用空白节点(尽管如果您使用xsl:strip-space

，这可能会被删除)。

 <xsl:key name="term" match="datafield[@tag='151']" use="subfield[@code='a']" />

下一个问题是您对tt50a变量的定义。您确实希望在这里使用相对表达式，因为此时它将在文档中的任何位置拾取第一个匹配元素。您应该这样做(这是因为您现在位于550节点上)

<xsl:variable name="t550a" select="subfield[@code='a']" />

但是，看起来您实际上并没有使用这个变量。当前使用的键key('term','$550a')使用的是字符串字面值，而不是变量。您可能想要这样做:

<xsl:for-each select="key('term',$t550a)">

最后，在xsl:for-each中，您执行//controlfield[@tag='001']，然后选择文档中的第一个controlfield。我认为你只想选择当前record中的一个。由于record是当前datafield的父级，您可以这样做:

<xsl:value-of select="../controlfield[@tag='001']" />

试试这个XSLT

<xsl:stylesheet version="1.0" xmlns:marc="http://www.loc.gov/MARC21/slim" xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"  xmlns:dc="http://purl.org/dc/elements/1.1/"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="rdf dc marc">
 <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
 <xsl:key name="term" match="datafield[@tag='151']" use="subfield[@code='a']" />
 <xsl:template match="datafield[@tag='550'][subfield[@code='a']]">
   <xsl:variable name="t550a" select="subfield[@code='a']" />
   <xsl:copy>
     <xsl:apply-templates select="@*|node()"/>
     <xsl:for-each select="key('term',$t550a)">
       <subfield code="0">
         <xsl:value-of select="../controlfield[@tag='001']" />
       </subfield>
      </xsl:for-each>
    </xsl:copy>
 </xsl:template>
 <xsl:template match="@*|node()">
  <xsl:copy>
   <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
 </xsl:template>    
</xsl:stylesheet>

这不会完全给出问题中显示的输出，因为您的输入XML只有一个550节点。

Answer 2

使用我的xslt，似乎数据字段标记151正在被删除。

是的，这是正确的，因为这是你指示它做的:

 <xsl:template match="//datafield[@tag='151'][subfield[@code='a']]">
  <xsl:variable name="t550a" select="//datafield[@tag='550'][subfield[@code='a']]" />
  <xsl:for-each select="key('term','$550a')">
   <xsl:value-of select="//controlfield[@tag='001']" />
  </xsl:for-each>
 </xsl:template>

这意味着:当datafield匹配时，遍历值为$550a的所有项，并在每次迭代中选择(从根!)所有控制字段的值。我假设您更愿意使用当前节点的控制字段，如.//controlfield.... ?

但是这里没有创建任何元素。如果你想要这个，你应该加上这个。例如:

 <xsl:template match="//datafield[@tag='151'][subfield[@code='a']]">
  <xsl:variable name="t550a" select="//datafield[@tag='550'][subfield[@code='a']]" />
  <xsl:copy>
    <xsl:for-each select="key('term','$550a')">
      <xsl:value-of select="//controlfield[@tag='001']" />
    </xsl:for-each>
   </xsl:copy>
 </xsl:template>

将复制datafield .