Emacs和ansi术语:Elisp遍历缓冲区列表

Question

我正在使用以下代码来打开ansi术语。我在这里找到的。

(require 'term)
(defun visit-ansi-term ()
  "If the current buffer is:
     1) a running ansi-term named *ansi-term*, rename it.
     2) a stopped ansi-term, kill it and create a new one.
     3) a non ansi-term, go to an already running ansi-term
        or start a new one while killing a defunt one"
  (interactive)
  (let ((is-term (string= "term-mode" major-mode))
        (is-running (term-check-proc (buffer-name)))
        (term-cmd "/usr/local/bin/bash")
        (anon-term (get-buffer "*ansi-term*")))
    (if is-term
        (if is-running
            (if (string= "*ansi-term*" (buffer-name))
                (call-interactively 'rename-buffer)
              (if anon-term
                  (switch-to-buffer "*ansi-term*")
                (ansi-term term-cmd)))
          (kill-buffer (buffer-name))
          (ansi-term term-cmd))
      (if anon-term
          (if (term-check-proc "*ansi-term*")
              (switch-to-buffer "*ansi-term*")
            (kill-buffer "*ansi-term*")
            (ansi-term term-cmd))
        (ansi-term term-cmd)))))

(global-set-key (kbd "<f2>") 'visit-ansi-term)

现在我想修改它，这样在重命名缓冲区后，它会记住它的名称，并且当我使用键盘快捷键迭代重命名的缓冲区列表时。

因此，如果我按[F2]，它发现ansi术语正在运行，它会问我是否要重命名它。我重命名它，说BUILD。我想要一个函数并绑定到Say[F3]来遍历打开的ansi术语列表。

我是ELISP文盲。如果有人能提供参考资料，我会很高兴的。

谢谢。

Answer 1

以下代码/绑定循环通过主模式为term-mode:的所有缓冲区

(global-set-key (kbd "<f3>") 'cycle-ansi-term)
(defun cycle-ansi-term ()
  "cycle through buffers whose major mode is term-mode"
  (interactive)
  (when (string= "term-mode" major-mode)
    (bury-buffer))
  (let ((buffers (cdr (buffer-list))))
    (while buffers
      (when (with-current-buffer (car buffers) (string= "term-mode" major-mode))
        (switch-to-buffer (car buffers))
        (setq buffers nil))
      (setq buffers (cdr buffers)))))