细化XSL代码

Question

我必须对XML文档中相同节点的子节点进行分组(合并)。我发现了一个类似的主题，我得到了一些示例代码，但是我的XML更复杂和扭曲，我需要真正理解以下XSL代码的语法逻辑:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:key name="group-data" match="GroupData" use="concat(@ID, '___', @Key)" />
  <xsl:template match="/">
    <Groups>
      <!--
      Iterate over a node set containing just one GroupData element for
      each combination of ID and Key
      -->
      <xsl:for-each select="/Groups/GroupData[count( . | key('group-data', concat(@ID, '___', @Key))[1]) = 1]">
        <GroupData>
          <!-- Copy attributes from the "prototype" GroupData -->
          <xsl:copy-of select="@*"/>
          <!--
          Copy ItemData children from *all* GroupData elements with matching
          ID/Key
          -->
          <xsl:copy-of select="key('group-data', concat(@ID, '___', @Key))/ItemData" />
        </GroupData>
      </xsl:for-each>
    </Groups>
  </xsl:template>
</xsl:stylesheet>

该XSL的示例 XML代码为:

<GroupData ID="xxx" Key="4" Temp="yyy">
        <ItemData ID="zzz" Value="3"/>
    </GroupData>
    <GroupData ID="yyy" Key="4" Temp="yyy">
        <ItemData ID="abc" Value="3"/>
    </GroupData>
    <GroupData ID="zzz" Temp="yyy">
        <ItemData ID="pqr" Value="1982"/>
    </GroupData>
    <GroupData ID="zzz" Temp="yyy">
        <ItemData ID="tuv" Value="1982"/>
    </GroupData>

因此，我想了解XSL代码，以便将其应用于我的情况。

谁能给我详细说明一下吗?更准确地说，这些部分:

<xsl:key name="group-data" match="GroupData" use="concat(@ID, '___', @Key)" />

和

<xsl:for-each select="/Groups/GroupData[count( . | key('group-data', concat(@ID, '___', @Key))[1]) = 1]">
        <GroupData>
          <!-- Copy attributes from the "prototype" GroupData -->
          <xsl:copy-of select="@*"/>
          <!--
          Copy ItemData children from *all* GroupData elements with matching
          ID/Key
          -->
          <xsl:copy-of select="key('group-data', concat(@ID, '___', @Key))/ItemData" />
        </GroupData>
      </xsl:for-each>

Answer 1

<xsl:key name=""/>使用指定的表达式作为查找键，在文档中创建xml节点的索引。这是为了更容易地找到相似的节点。在XSL 1中。X，这是分组节点的主要手段。

使用key(name, key)查询该索引。

在你的情况下

/Groups/GroupData[count( . | key('group-data', concat(@ID, '___', @Key))[1]) = 1]

的基本意思是:查找指定键在索引中排在第一位的所有GroupData节点。也可以写成:

/Groups/GroupData[generate-id() = generate-id(key('group-data', concat(@ID, '___', @Key))[1])]

generate-id()方法为文档中的任何节点创建一个惟一的id。它使得比较节点是否相等成为可能。如果没有提供参数，它将使用活动节点(.)