正确使用逻辑语言作为工具

Question

我对编程中的"使用正确的工具完成工作"的哲学很感兴趣，我有一个我认为可以通过逻辑编程解决的问题。我的意思是天真的，因为我没有做过任何逻辑编程，只是开始学习。但是，在我仍在尝试掌握概念和词汇的阶段，我希望在可能变得太深入之前获得一些专家指导。

吸引我使用逻辑编程的想法是我对"统一"概念的模糊知识，但我的想法是以一种我不确定是惯用语或正确的方式使用它。给定两个对象(或树(，我想通过它们的属性(或叶子(比较两者的相等性，而我想返回的是一些"差异"的概念——即，鉴于这两个对象没有不同的方式，其中一个必须进行哪些更改才能使两者成为某种相等的概念？

例如，假设我有两个对象chair和stool。假设每个都由属性或属性列表组成，我想构建一个系统，该系统可以返回类似"如果凳子的legCount4并且hasBacktrue，椅子和凳子将是相等的"。

出于某种原因，从语义上讲，我将其想象为一种余数，例如，chair减去stool等于一leg。不确定这是否有帮助...

我可以想到一些愚蠢的方法，用命令式代码来做到这一点，也可以想到一些更优雅的方法来使用函数式技术来做到这一点，但我有一种预感，逻辑编程可能特别适合这个。任何关于研究方向的智慧将不胜感激，谢谢！

Answer 1

可能你想从ILP文献中研究"最不一般的概括"或"反统一"：

以下是一些幻灯片： http://soft.vub.ac.be/~cderoove/declarative_programming/decprog7.pdf

使用简单逻辑第 9 章中的代码 http://people.cs.bris.ac.uk/~flach/SL/SL.pdf：

:-op(600,xfx,'<-').
anti_unify(Term1,Term2,Term):-
anti_unify(Term1,Term2,Term,[],S1,[],S2).
anti_unify(Term1,Term2,Term1,S1,S1,S2,S2):-
Term1 == Term2,!.
anti_unify(Term1,Term2,V,S1,S1,S2,S2):-
subs_lookup(S1,S2,Term1,Term2,V),!.
anti_unify(Term1,Term2,Term,S10,S1,S20,S2):-
nonvar(Term1),nonvar(Term2),
functor(Term1,F,N),functor(Term2,F,N),!,
functor(Term,F,N),
anti_unify_args(N,Term1,Term2,Term,S10,S1,S20,S2).
anti_unify(T1,T2,V,S10,[T1<-V|S10],S20,[T2<-V|S20]).

anti_unify_args(0,Term1,Term2,Term,S1,S1,S2,S2).
anti_unify_args(N,Term1,Term2,Term,S10,S1,S20,S2):-
N>0, N1 is N-1,
arg(N,Term1,Arg1),
arg(N,Term2,Arg2),
arg(N,Term,Arg),
anti_unify(Arg1,Arg2,Arg,S10,S11,S20,S21),
anti_unify_args(N1,Term1,Term2,Term,S11,S1,S21,S2).
subs_lookup([T1<-V|Subs1],[T2<-V|Subs2],Term1,Term2,V):-
T1 ==Term1,
T2 ==Term2,!.
subs_lookup([S1|Subs1],[S2|Subs2],Term1,Term2,V):-
subs_lookup(Subs1,Subs2,Term1,Term2,V).

然后，您可以查询：

?- anti_unify(object(type=chair,legs=4,hasback=true,color=red),object(type=stool,legs=3,hasback=false,color=red),T,[],S1,[],S2).
T = object(type=_1838, legs=_1808, hasback=_1778, color=red),
S1 = [chair<-_1838, 4<-_1808, true<-_1778],
S2 = [stool<-_1838, 3<-_1808, false<-_1778] .

这给了你一个术语，它是我们两个对象的最不一般的概括，以及你为取回对象而进行的替换。