如何使用Perl在目录及其所有子目录中找到最新的.pl文件?

Question

如何使用Perl扫描整个目录的内容，包括其子目录的内容，并在其中找到最新的.pl文件?

我想建立一个目录树中所有.pl文件的完整文件路径的排序数组/列表。

因此，例如，如果我的基本目录是/home/users/cheeseconqueso/，我想在该目录和该路径内的任何子目录中搜索.pl文件，然后按日期对.pl文件进行排序。

最终结果将是一个数组@pl_paths，其中$pl_paths[0]将类似于/home/users/cheeseconqueso/maybe_not_newest_directory/surely_newest_file.pl

从这个结果，我想执行文件，但我认为一旦我得到排序数组计算出来，在$pl_paths[0]中执行文件，不会有问题。

在SO上有一个类似的问题，我一直在努力修改以满足我的需要，但我现在在这里的原因很明显。

我用来在一个目录中获取最新文件名的代码是:

opendir(my $DH, $DIR) or die "Error opening $DIR: $!";
my %files = map { $_ => (stat("$DIR/$_"))[9] } grep(! /^..?$/, readdir($DH));
closedir($DH);
my @sorted_files = sort { $files{$b} <=> $files{$a} } (keys %files);
print $sorted_files[0]."n";

Answer 1

如果你想要一个核心模块，你可以使用File::Find，但我更喜欢使用File::Find::Rule。

首先，我们可以找到目录下的所有.pl文件

use File::Find::Rule;
my @files = File::Find::Rule->file
                            ->name('*.pl')
                            ->in($directory);

然后让我们使用map将文件名与其修改时间关联起来:

my @files_with_mtimes = map +{ name => $_, mtime => (stat $_)[9] }, @files;

并按mtime:

排序

my @sorted_files = reverse sort { $a->{mtime} <=> $b->{mtime} } 
                @files_with_mtimes;

从那里，最新的名字是在$sorted_files[0]{name}。

如果你只想找到最上面的那个，实际上没有必要做一个完整的排序，但我能想到的最好的解决方案涉及一些稍微高级的FP，所以如果你觉得它看起来很奇怪，不要担心:

use List::Util 'reduce';
my ($top_file) = reduce { $a->{mtime} >= $b->{mtime} ? $a : $b } 
  @files_with_mtimes;

Answer 2

使用File::Find::Rule和Schwartzian变换，您可以在从dir_path开始的子树中获得扩展名为.pl的最新文件。

#!/usr/bin/env perl
use v5.12;
use strict;
use File::Find::Rule;
my @files = File::Find::Rule->file()->name( '*.pl' )->in( 'dir_path' );
# Note that (stat $_ )[ 9 ] yields last modified timestamp
@files = 
   map { $_->[ 0 ] }
   sort { $b->[ 1 ] <=> $a->[ 1 ] }
   map { [ $_, ( stat $_ )[ 9 ] ] } @files;
# Here is the newest file in path dir_path
say $files[ 0 ];

map-sort-map链是一个典型的习惯用法:获取时间戳很慢，所以我们对每个文件只做一次，将每个时间戳与其文件保存在一个arrayref中。然后使用时间戳对新列表进行排序(比较每个arrayref的第二个元素)，最后丢弃时间戳，只保留文件名。

Answer 3

使用File::Find核心模块