Delphi-无法将TObjectList保存/加载到FileStream

Question

我有一个TObjectList，我正在尝试将它写入磁盘。虽然我最终得到了一个文件（54字节），但当我将FNAME属性值更改为非常长的值时，文件的大小永远不会改变，当我尝试读取它时，我会得到零。我不知道出了什么问题。很抱歉代码片段太长。很容易理解发生了什么，只是我不明白为什么它没有做我想做的事。

type
  { Declare a new object type. }
  TNewObject = class(TComponent)
  private
    FName: String;
  public
    property BizName: String read FName write FName;
    constructor Create(const AName: String);
    destructor Destroy(); override;
  end;

为我的TObjectList 声明一个全局变量

var
  Form1: TForm1;
  List: TObjectList<TNewObject>;

声明我的构造函数和析构函数。。

constructor TNewObject.Create(const AName: String);
begin
  FName := AName;            
end;
destructor TNewObject.Destroy;
begin      
  inherited;
end;

现在添加一个按钮来创建我的对象。。。

procedure TForm1.CreateButtonClick(Sender: TObject);  
    var     
      Obj: TNewObject;
    begin
      { Create a new List. }
      { The OwnsObjects property is set by default to true -- the list will free the owned objects automatically. }
      List := TObjectList<TNewObject>.Create();
      { Add some items to the List. }
      List.Add(TNewObject.Create('One'));
      List.Add(TNewObject.Create('Two'));
      { Add a new item, but keep the reference. }
      Obj := TNewObject.Create('Three');
      List.Add(Obj);
end;

现在添加一个保存按钮

procedure TForm1.SaveButtonClick(Sender: TObject);
var
  i: Integer;
  fs: TfileStream;
begin
  if SaveDialog1.Execute then
  begin
    fs := TfileStream.Create(SaveDialog1.FileName, fmCreate);
    try
      for i := 0 to List.Count - 1 do
      begin
        ShowMessage(List[i].BizName);
        fs.WriteComponent(TNewObject(List[i]));            
      end;
    finally
      fs.Free;
    end;
  end;
end;

CAVEATS：我知道只有公共财产才会被保存。。。应该是BIZNAME。保存时，这3个条目确实会显示在SHOWMESSAGE中。。。。

我确实记得我的班级登记。

Initialization
RegisterClass(TNewObject); 

为了完整起见，这也是我的加载例程。。。

procedure TForm1.LoadButtonClick(Sender: TObject);
var
  i: Integer;
  fs: TfileStream;
  vRecord: TNewObject;
begin
  if OpenDialog1.Execute then
  begin
    List.Clear; // clear list
    fs := TfileStream.Create(OpenDialog1.FileName, fmopenRead);
    try
      while fs.Position < fs.size do
      begin
        vRecord := TNewObject(fs.ReadComponent(nil));
        ShowMessage(vRecord.FName);           
        List.Add(vRecord);
      end;
    finally
      fs.Free;
    end;
    ShowMessage(IntToStr(List.Count));
  end;
end;

谢谢你的帮助。

Answer 1

组件流系统仅流式传输已发布的属性，您需要发布"BizName"。

或者，您可以覆盖DefineProperties来决定要流式传输的其他内容。

type
  TNewObject = class(TComponent)
  private
    FName: String;
    procedure ReadName(Reader: TReader);
    procedure WriteName(Writer: TWriter);
  protected
    procedure DefineProperties(Filer: TFiler); override;
  public
    property BizName: String read FName write FName;
    ...
procedure TNewObject.ReadName(Reader: TReader);
begin
  FName := Reader.ReadString;
end;
procedure TNewObject.WriteName(Writer: TWriter);
begin
  Writer.WriteString(FName);
end;
procedure TNewObject.DefineProperties(Filer: TFiler);
begin
  inherited;
  Filer.DefineProperty('bizname', ReadName, WriteName, FName <> '');
end;