增大图形圆的大小

Question

我目前正在尝试使用graphics.linestyle和graphics.drawCircle通过鼠标点击来制作一个圆圈。鼠标点击后，我希望圆圈在舞台上展开，直到半径达到150。我尝试过使用此代码，但没有使其发挥作用。

import flash.events.MouseEvent;
import flash.display.Sprite;
import flash.events.Event;
var circle:Sprite = new Sprite();
knapp.addEventListener(MouseEvent.CLICK, push);
function push (evt:MouseEvent) {
    var radius:Number = 10;
    var incRadius:Number = 3;
    circle.graphics.lineStyle(3, 0xff000, 1);
    circle.graphics.drawCircle(200, 200, radius);
    addChild(circle);
    circle.addEventListener(Event.ENTER_FRAME, increase);
    function increase (evt:Event) {
        if (radius <= 150) {
            radius += incRadius;
        }
    }
}

Answer 1

• 将嵌套函数弹出到全局命名空间中
• 将重复出现的变量设为全局变量
• 增加radius后，需要重新绘制圆
• 因为您只绘制边，所以每次更新时都需要清除圆
• 动画完成后删除了未使用的事件侦听器

这将修复它。你可以在一个空白项目中运行它，它将编译并工作。只要点击背景上的任何位置，它就会运行。

import flash.events.MouseEvent;
import flash.display.Sprite;
import flash.events.Event;
var circle:Sprite = new Sprite();
addChild(circle);
var radius:Number = 10;
var incRadius:Number = 3;
stage.addEventListener(MouseEvent.CLICK, push);
function push(e:MouseEvent) {
    radius = 10;
    circle.graphics.clear();
    circle.graphics.lineStyle(3, 0xff000, 1);
    circle.graphics.drawCircle(0, 0, radius);
    circle.x = stage.mouseX;
    circle.y = stage.mouseY;
    circle.addEventListener(Event.ENTER_FRAME, increase);
}
function increase(e:Event) {
    radius += incRadius;
    if (radius > 150) {
        circle.removeEventListener(Event.ENTER_FRAME, increase);
    } else {
        circle.graphics.clear();
        circle.graphics.lineStyle(3, 0xff000, 1);
        circle.graphics.drawCircle(0, 0, radius);
    }
}