教堂中的共享内存 n 体模拟

Question

>我正在尝试重新实现 Peter Pacheco 的并行编程简介第 6.1.6 章中介绍的 n 体模拟的共享内存实现。在该章中，它是使用OpenMP实现的。

这是我使用 OpenMP 的并行实现。这是使用Chapel的串行实现。我在使用 Chapel 实现共享内存并行实现时遇到问题。由于无法在forall循环中获取线程的排名，因此我无法使用与 OpenMP 实现中相同的方法。我必须使用coforall循环，创建任务并手动分发迭代。这似乎不切实际，并表明在教堂内有一种更优雅的方法来解决这个问题。

我正在寻找有关如何使用Chapel提供的工具更好地解决此问题的指导和建议。

Answer 1

我的建议是在 forall-loop 中使用 (+( reduce意图对forces，这将为每个任务提供自己的私有forces副本，然后(总和(在任务完成时将其单独的副本减少回原始forces变量。 这可以通过将以下 with-子句附加到您的 forall 循环来完成：

forall q in 0..#n_bodies with (+ reduce forces) {

在这里，我寻找其他方法来使代码更加优雅，并建议针对此问题从 2D 数组更改为数组数组，以便将 x、y、z 组件的三重相似代码语句折叠为单个语句。 我还利用了您的pDomain变量并为[0..#3] real创建了一个类型别名，以消除代码中的一些冗余。 哦，我删除了Math和IO模块的use，因为它们在教堂程序中自动使用。

这就是留给我的地方：

config const filename = "input.txt";
config const iterations = 100;
config const out_filename = "out.txt";
const X = 0;
const Y = 1;
const Z = 2;
const G = 6.67e-11;
config const dt = 0.1;
// Read input file, initialize bodies                                       
var f = open(filename, iomode.r);
var reader = f.reader();
var n_bodies = reader.read(int);
const pDomain = {0..#n_bodies};
type vec3 = [0..#3] real;
var forces: [pDomain] vec3;
var velocities: [pDomain] vec3;
var positions: [pDomain] vec3;
var masses: [pDomain] real;
for i in pDomain {
positions[i] = reader.read(vec3);
velocities[i] = reader.read(vec3);
masses[i] = reader.read(real);
}
f.close();
reader.close();
for i in 0..#iterations {
// Reset forces                                                           
forces = [0.0, 0.0, 0.0];
forall q in pDomain with (+ reduce forces) {
for k in pDomain {
if k <= q {
continue;
}
var diff = positions[q] - positions[k];
var dist = sqrt(diff[X]**2 + diff[Y]**2 + diff[Z]**2);
var dist_cubed = dist**3;
var tmp = -G * masses[q] * masses[k] / dist_cubed;
var force_qk = tmp * diff;
forces[q] += force_qk;
forces[k] -= force_qk;
}
}

forall q in pDomain {
positions[q] += dt * velocities[q];
velocities[q] += dt / masses[q] * forces[q];
}
}
var outf = open(out_filename, iomode.cw);
var writer = outf.writer();
for q in pDomain {
writer.writeln("%er %er %er %er %er %er".format(positions[q][X], positions[q][Y], positions[q][Z], velocities[q][X], velocities[q][Y], velocities[q][Z]));
}
writer.close();
outf.close();

您可以考虑进行的另一个更改是将更新位置和速度的 forall-loop 替换为以下全数组语句：

positions += dt * velocities;                                           
velocities += dt / masses * forces;                                     

其中主要的权衡是 forall 将使用单个并行循环以融合方式实现语句，而整个数组语句不会(至少在当前版本 1.18 版本的编译器中(。