Clojure Quil:绘制线条时嵌套循环

Question

我在找出Clojure Quil库中的算法时遇到了严重的问题。我一直在尝试用功能中间件模式制作一些网络/群集模式的图表。我的问题是，如何在Quild中创建一个嵌套的"for循环"，以便用一条线将任何给定点连接到任何其他点?区别在于1->2 -> 3->4…等和连接1->2 1->3 1->4 2->3 2->4等的集合

我的程序看起来像这样，虽然我已经试图编辑它是通用的为了这个问题的目的。

(ns stack-question.core
  (:require [quil.core :as q]
            [quil.middleware :as m]))   
;how to draw the point
(defn draw-points [point]
  (q/point (:x point) (:y point)))
;the main data structure
(defn make-point [num]
  {:name num
   :x (rand 500.0)
   :y (rand 500.0)})    
;draws connections between two objects
(defn connections [p1 p2]
      (q/stroke 200 200 100 150)
      (q/line (:x p1) (:y  p1) (:x p2) (:y p2)))))
(defn setup []
  (q/frame-rate 30)
  {:points (map make-points (take 1000 (range)))})
;this function isn't important to the question 
;but let's just say that the points move position each frame 
(defn update-state [state]
  (update state :points move-group))
;this is the problem function here.
;I'm trying to map over the collection, but with a fixed head
;and do so for each element in the collection
(defn make-conts [coll]
  (loop [x coll]
    (when (not (empty? (rest coll)))
      (map (partial connections (first x)) (rest x))
      (recur (rest x)))))

(defn draw-state [state]
  (do
    ;(q/frame-rate 1)
    (q/background 0)
    (doseq [x (map draw-point (:points state))] x)
    (doseq [x (make-conts (:points state))] x)))
(q/defsketch stack-question
  :title "GL"
  :size [500 500]
  :setup setup
  :update update-state
  :draw draw-state
  :middleware [m/fun-mode]
  :renderer :opengl)

我希望这不是完全不透明。

Answer 1

你的代码有两个问题:

第一个是在when语句中检查(rest coll)而不是(rest x)，导致无限循环。

第二个是map返回一个惰性序列，这意味着对connections的调用没有发生。这可以通过用doall包装对map的调用来解决，但是由于您对副作用感兴趣，而不是返回值，因此应该使用doseq。

这个版本的函数(多余的loop也被删除了)应该可以工作了:

(defn make-conts [coll]
    (when (not (empty? (rest coll)))
      (doseq [endpoint (rest coll)]
        (connections (first coll) endpoint))
      (recur (rest coll))))

您可以使用clojure.math.combinatorics中的combinations来代替自己编写代码来生成组合:

(require '[clojure.math.combinatorics :as combi])
(defn make-conts [coll]
   (doseq [[p1 p2] (combi/combinations coll 2)]
     (connections p1 p2)))