使用 XSL 设置文档簿过程的一部分样式

Question

我试图影响 docbook 5 过程中 fo：list-block 的属性。我想做的是采用以下文档手册XML代码：

<procedure>
    <title>Eating a banana</title>
    <step><para>Find banana</para></step>
    <step><para>Peel banana</para></step>
    <step><para>Stick banana in mouth</para></step>
<procedure>

并且仅影响步骤（列表）的 FO 输出，而不会影响标题。

使用这个：

<xsl:template match="d:procedure">
    <fo:block border-left-width="1pt" border-left-style="solid" padding-left="0.25in">
        <xsl:apply-imports />
    </fo:block>
</xsl:template>

给我这样的东西：

|
| Procedure 1: Eating a banana
|   1. Find banana
|   2. Peal banana
|   3. Stick banana in mouth
|

我想得到的是：

Procedure 1: Eating a banana
  |   1. Find banana
  |   2. Peal banana
  |   3. Stick banana in mouth

尝试匹配<step>是无效的，因为 docbook 将它们转换为 fo：list-block（fo:block作为fo:list-block的后代会产生"无效子"错误）。

Docbook 有一个用于<procedures>的 xsl：attribute-set ，但据我所知，它只能用于设置整个块的样式（类似于模板 match='d：procedure'，而不仅仅是列表。

Answer 1

这是如何完成的。

1. 将此版本的"过程"模板（原始模板位于 lists.xsl 中）添加到自定义层：

   <xsl:template match="d:procedure">
     <xsl:variable name="id">
       <xsl:call-template name="object.id"/>
     </xsl:variable>
     <!-- Preserve order of PIs and comments -->
     <xsl:variable name="preamble"
           select="*[not(self::d:step
                     or self::d:title
                     or self::d:titleabbrev)]
                   |comment()[not(preceding-sibling::d:step)]
                   |processing-instruction()[not(preceding-sibling::d:step)]"/>
     <xsl:variable name="steps" 
                   select="d:step
                           |comment()[preceding-sibling::d:step]
                           |processing-instruction()[preceding-sibling::d:step]"/>
     <xsl:call-template name="formal.object.heading"/>  
     <fo:block id="{$id}" xsl:use-attribute-sets="procedure.properties list.block.spacing"
           border-left-width="1pt" border-left-style="solid" padding-left="0.25in">
       <xsl:apply-templates select="$preamble"/>
       <fo:list-block xsl:use-attribute-sets="list.block.spacing"
                      provisional-distance-between-starts="2em"
                      provisional-label-separation="0.2em">
         <xsl:apply-templates select="$steps"/>
       </fo:list-block>
     </fo:block>
   </xsl:template>
   

   <xsl:call-template name="formal.object.heading"/>（返回带有过程标题的fo:block）在输出带有边框的块之前执行。我还通过删除处理标题放置的代码来简化模板。

2. 将文本缩进添加到formal.title.properties属性集：

   <xsl:attribute-set name="formal.title.properties" 
                  use-attribute-sets="normal.para.spacing">
     <xsl:attribute name="text-indent">
       <xsl:choose>
         <xsl:when test="self::d:procedure">-30pt</xsl:when>
         <xsl:otherwise>0pt</xsl:otherwise>
       </xsl:choose>
     </xsl:attribute>
   </xsl:attribute-set>
   

这会将过程标题推到左侧（但保留其他标题）。

Answer 2

我想出了这个主意。虽然它适用于单级过程，但任何带有子步骤的内容都会导致问题。

<xsl:template match="d:step">
    <fo:list-item margin-left="0.25in" padding-left='1em' border-left-width='2pt' border-left-color="gray" border-left-style='solid'>
        <fo:list-item-label start-indent="0.40in" end-indent="label-end()">
            <fo:block>
                <xsl:number format="1."/>
            </fo:block>
        </fo:list-item-label>       
        <fo:list-item-body start-indent="3.5pc">
            <fo:block>
                <xsl:apply-templates />
            </fo:block>
        </fo:list-item-body>
    </fo:list-item>
</xsl:template>