XSLT否则循环无法正常工作

Question

我正在尝试用XSLT代表一个表，其中输入字段可以是text或number。我在XML A中包含包含列和行号的标签。在headerName标签中，我有表的标题信息。

这是我的XML的一个示例：

<elements>
       <element type="TABLE">
            <id>table2</id>
            <order>49</order>
            <table>
                <colNumber>2</colNumber>
                <headerName>
                    <amount>false</amount>
                    <value>Header1</value>
                </headerName>
                <headerName>
                    <amount>true</amount>
                    <value>Header2</value>
                </headerName>
                <rowNumber>2</rowNumber>
            </table>
        </element>
</elements>

现在，我正在使用的XSLT是：

<xsl:for-each select="elements/element">
    <xsl:if test="@type='TABLE'">
        <div data-order="{order}" id="{id}">
            <table class="table table-bordered mt-lg">
                <thead>
                    <tr>
                        <xsl:for-each select="table/headerName">
                            <td>
                                <xsl:value-of select="value"/>
                            </td>
                        </xsl:for-each>
                    </tr>
                </thead>
                <tbody>
                    <xsl:variable name="rows" select="table/rowNumber/text()"/>
                    <xsl:variable name="cols" select="table/colNumber/text()"/>
                    <xsl:variable name="amount" select="table/headerName/amount/text()"/>
                    <xsl:for-each select="(//node())[$rows &gt;= position()]">
                        <tr>
                            <xsl:for-each select="(//node())[$cols &gt;= position()]">
                                <td>
                                    <xsl:choose>
                                        <xsl:when test="$amount = 'false'">
                                            <input type="text"/>
                                        </xsl:when>
                                        <xsl:otherwise>
                                            <input type="number"/>
                                        </xsl:otherwise>
                                    </xsl:choose>
                                </td>
                            </xsl:for-each>
                        </tr>
                    </xsl:for-each>
                </tbody>
            </table>
        </div>
    </xsl:if>
</xsl:for-each>

我的预期输出是：

<div data-order="49" id="table2">
    <table class="table table-bordered mt-lg">
        <thead>
            <tr>
                <td>
                    Header1
                </td>
                <td>
                    Header2
                </td>
            </tr>
        </thead>
        <tbody>
            <tr>
                <td><input type="text"></input></td>
                <td><input type="number"></input></td>
            </tr>
            <tr>
                <td><input type="text"></input></td>
                <td><input type="number"></input></td>
            </tr>
        </tbody>
    </table>
</div>

我没有看到错误在哪里，我尝试使用XPath表达式，但我总是得到<input type="text"/>

Answer 1

在设置变量amount时，您要在xsl:for-each语句之前进行操作，因此只能将其设置为XML中第一个table/headerName的值，您确实需要移动在最内部的xsl:for-each中声明，因为您希望您需要基于当前列号设置它。

但是，您需要考虑到那时不会将其放置在element元素上，因此您需要首先将element的引用存储在变量中，因此您可以在内部的内部访问它xsl:for-each

尝试此XSLT片段

<tbody>
    <xsl:variable name="rows" select="table/rowNumber/text()"/>
    <xsl:variable name="cols" select="table/colNumber/text()"/>
    <xsl:variable name="node" select="." />
    <xsl:for-each select="(//node())[$rows &gt;= position()]">
        <tr>
            <xsl:for-each select="(//node())[$cols &gt;= position()]">
                <xsl:variable name="position" select="position()" />
                <xsl:variable name="amount" select="$node/table/headerName[position() = $position]/amount/text()"/>
                <td>
                    <xsl:choose>
                        <xsl:when test="$amount = 'false'">
                            <input type="text"/>
                        </xsl:when>
                        <xsl:otherwise>
                            <input type="number"/>
                        </xsl:otherwise>
                    </xsl:choose>
                </td>
            </xsl:for-each>
        </tr>
    </xsl:for-each>
</tbody>

我猜您知道，如果rowNumber或colNumber超过XML中的节点数。