无法在 xsl:node-set 之后提取数据

Question

我简化了以下一段XSL，以更好地说明我的问题。在这里：

<?xml version="1.0" encoding="utf-8"?>
  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"  exclude-result-prefixes="msxsl"
  xmlns:exsl="http://exslt.org/common"
  >
  <xsl:output method="xml"  doctype-public="..." doctype-system="..." indent="yes"/>
  <xsl:template match="/">
  <xsl:variable name="tmpTotal">
    <root>
      <items>
        <item>1</item>
        <item>2</item>
        <item>3</item>
        <item>4</item>
      </items>
    </root>
  </xsl:variable>
  <xsl:variable name="myTotal" select="exsl:node-set($tmpTotal)"/>
  All values:<xsl:copy-of select="($myTotal)/*"/>
  <xsl:for-each select="($myTotal)/items/item">
    Item value:<xsl:value-of select="."/>
  </xsl:for-each>
  Item count:<xsl:value-of select="count(($myTotal)/items/item)"/>
  Item total:<xsl:value-of select="sum(($myTotal)/items/item)"/>
 </xsl:template>
</xsl:stylesheet>

我知道这些值在节点中，因为 xsl：copy-of 选择工作。但是，当我尝试获取任何其他值（包括项目值、项目计数和项目总计）时，我没有得到任何值。任何人都可以帮助我解决这个问题吗？我花了将近一天的时间，不明白为什么我没有得到任何价值。提前谢谢。

Answer 1

您忘了包含root元素。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
  xmlns:exsl="http://exslt.org/common"
  exclude-result-prefixes="msxsl exsl xsl">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*" />    
<xsl:template match="/">
  <xsl:variable name="tmpTotal">
    <root>
      <items>
        <item>1</item>
        <item>2</item>
        <item>3</item>
        <item>4</item>
      </items>
    </root>
  </xsl:variable>
  <xsl:variable name="myTotal" select="exsl:node-set($tmpTotal)"/>
  All values:<xsl:copy-of select="($myTotal)/*"/>
    <xsl:for-each select="($myTotal)/root/items/item">
    Item value:<xsl:value-of select="."/>
  </xsl:for-each>
    Item count:<xsl:value-of select="count(($myTotal)/root/items/item)"/>
    Item total:<xsl:value-of select="sum(($myTotal)/root/items/item)"/>
 </xsl:template>
</xsl:stylesheet>

输出。。。

  All values:<root><items><item>1</item><item>2</item><item>3</item><item>4</item></items></root>
    Item value:1
    Item value:2
    Item value:3
    Item value:4
    Item count:4
    Item total:10