通过Xquery更改节点名称

Question

我正在尝试创建一个xquery，每当'cnode3'is'ccvalue1时'。

<PNode>
  <CNode1>Node1</CNode1>
  <CNode2>Node2</CNode2>
  <CNode3>
     <CCNode1>CCValue1</CCNode1>
     <CCNode2>CCValue2</CCNode2>
  </CNode3>
  <CNode3>
     <CCNode1>CCValue3</CCNode1>
     <CCNode2>CCValue4</CCNode2>
  </CNode3></PNode>

在这种特定情况下，在线上没有得到太多帮助。我检查了下面的链接，但它将所有" cnode3''的名称更改为" changeNode3"。PFB链接：http://www.xqueryfunctions.com/xq/functx_change-element-names-deep.html

Answer 1

functx:change-element-names-deep()函数仅评估元素名称。您需要更多的自定义。

您可以在本地函数中使用TypesWitch：

declare function local:transform($nodes as node()*) as item()* {
    for $node in $nodes
    return 
        typeswitch($node)
            case text() return $node
            case comment() return $node
            case attribute() return $node
            case processing-instruction() return $node
            case element(CNode3) 
              return 
                if ($node[CCNode1 eq "CCValue1"]) then 
                  element ChangedNode3 {( $node/@*, local:transform($node/node()) )} 
                else 
                  element {name($node)} {($node/@*, local:transform($node/node()))}
            case element() 
              return element {name($node)} {($node/@*, local:transform($node/node()))}
            default return local:transform($node/node())
};

TypesWitch转换模式的完整描述。