嘿，我如何使用MIPS程序集精确地找到整数的平方根？
我们可以使用类似于为这个问题提交的算法，并根据需要进行调整。在进入MIPS之前，让我们看一下C:中的实现
//Function to compute sqroot(n)
int sqroot(int n) {
int x = n;
for (int i = 0; i < (n/2); i++)
x = (x + n / x) / 2;
return x;
}
sqroot(n)函数将计算与n的平方根的底相等的整数。因此，如果你调用sqroot(225)，你会得到预期的15，但sqroot(15)会返回3，而不是3.87298。
从C代码中，我们可以勾勒出MIPS代码的样子：
In calling function:
Load the number to be squared into $a0
jal root
root:
Initialize $t0 = n, $t1 = i = 0, $t2 = x = n = $a0, $t3 = n/2
Loop:
Divide n/x
Add x to n/x
Divide (x + n/x) by 2
Check if $t1 < $t3
If it is, branch back to loop
Else, move x into return register $v0
请注意：
- 确保根据需要推动和弹出堆栈。为了简单起见，我把它省略了
- 当除以2的幂时，可以使用srl指令
- 有关MIPS说明的说明和其他信息，请单击此处
当只使用整数操作时，我发现牛顿方法x = (x + n/x) / 2不令人满意，因为终止条件很难准确计算。n/2只是一个猜测，并且几乎总是超过必要的迭代次数。牛顿方法收敛于二次，并且与n不成正比，而是与sqrt(n)成正比。另一个建议，"一直重复直到x停止变化"也不起作用，因为对于非完美正方形，x将在根的底部和顶部之间交替——因为整数数学，当x比sqrt(n)稍小或稍大时，术语n/x将交替。
我从维基百科中采用了逐位数根计算方法，并创建了MIPS版本。它不存在低效率（n/2）或模糊性（floor(sqrt(n))或ceil(sqrt(n))）。查找表方法可以更有效地返回结果，但假设查找表不可用，这是一个好的、可靠的方法。
首先，我将C示例转换为只使用小于（<）的比较，因为MIPS只提供一个小于slt的集合比较指令。
int isqrt(int num) {
int ret = 0;
int bit = 1 << 30; // The second-to-top bit is set
// "bit" starts at the highest power of four <= the argument.
while (num < bit) {
bit >>= 2;
}
while (bit != 0) {
if (num < ret + bit) {
ret >>= 1;
} else {
num -= ret + bit;
ret = (ret >> 1) + bit;
}
bit >>= 2;
}
return ret;
}
以下是生成的MIPS代码：
isqrt:
# v0 - return / root
# t0 - bit
# t1 - num
# t2,t3 - temps
move $v0, $zero # initalize return
move $t1, $a0 # move a0 to t1
addi $t0, $zero, 1
sll $t0, $t0, 30 # shift to second-to-top bit
isqrt_bit:
slt $t2, $t1, $t0 # num < bit
beq $t2, $zero, isqrt_loop
srl $t0, $t0, 2 # bit >> 2
j isqrt_bit
isqrt_loop:
beq $t0, $zero, isqrt_return
add $t3, $v0, $t0 # t3 = return + bit
slt $t2, $t1, $t3
beq $t2, $zero, isqrt_else
srl $v0, $v0, 1 # return >> 1
j isqrt_loop_end
isqrt_else:
sub $t1, $t1, $t3 # num -= return + bit
srl $v0, $v0, 1 # return >> 1
add $v0, $v0, $t0 # return + bit
isqrt_loop_end:
srl $t0, $t0, 2 # bit >> 2
j isqrt_loop
isqrt_return:
jr $ra
你称之为任何其他MIPS程序：
addi $a0, $zero, 15
jal isqrt # v0 = result
此过程始终为正参数返回$v0 = floor(sqrt($a0))。
小心：代码进入负参数的无限循环。在调用此过程之前对您的输入进行消毒。
它不在MIPS中，但在汇编中。我发现的基本算法是基于前n个奇数加在一起=n^2的事实。
因此，如果你利用这一点，颠倒过程，从你想取的平方根的数字中减去，你可以循环得到确切的答案或近似值。我相信它是非完美平方的根+1。
这个想法是，你循环的次数是n，这是你的平方根。
希望这能有所帮助。
mov eax, 9513135 ; eax = number to take square root of
mov ebx, eax ; make a copy of eax in ebx
loopIt :
sub ebx, count ; count starts as 1, 3, 5, 7, 9
inc count ; count = even
inc count ; count = odd
inc sqrt ; gives sqrt value
mov eax, sqrt
cmp ebx, 0
js timetoReturn ; return value if signed num, aka goes over zero
jnz loopIt
timetoReturn :
mov reg, eax ; just outputting the value
您可以尝试此算法，它给出小于或等于数字平方根的整数。
假设您想要n的平方根。然后继续重复以下计算：
x = (x + n/x) / 2
选择x = n开始并不断重复，直到x停止变化。
这里有一个简单易懂的算法，用于计算C:中正整数平方根的底
int approx_sqrt(int x) {
int result;
for (int partialSum = 0, oddNum = 1; partialSum < x; partialSum += oddNum, oddNum +=2) result++;
return result;
}
它依赖于与okstory的答案相同的原则，只是方式略有不同。
理论：只要部分和小于操作数，递增的奇数就加到部分和上。结果等于奇数的数量相加以产生部分求和。
你们都错了。
您可以使用sqrt.s或sqrt.d程序集代码！ex）平方英尺$f12，$f13
不要把时间浪费在实现这些功能上。
如果要计算mips中整数的平方根，首先需要将整数转换为浮点值。假设你想取平方根的数字存储在$t1中，那么它到浮点的转换将看起来像这个
mtc1 $t1, $f1
cvt.s.w $f1, $f1
现在您可以使用sqrt.s函数计算平方根。
sqrt.s $f1,$f1
所以现在$f1将保存存储在$t1 中的整数的平方根