PL/SQL 在 for 循环中执行即时异常处理

Question

在下面的PL/SQL代码中，TABLE_ONE包含表名tname，列名cname和rowid rid。For 循环从 TABLE_ONE 中获取记录，并更新表 tname 中具有行 ID rid 的记录的列 cname。但是，如果要在 tname 中更新的记录被锁定，则 for 循环将卡住，并且不会处理来自TABLE_ONE的进一步记录。理想情况下，脚本忽略更新失败的记录并继续操作。请告知可能是什么问题。

BEGIN
    FOR c IN (SELECT * FROM TABLE_ONE a )
    LOOP
        DECLARE
            TNAME varchar2(30);
            CNAME varchar2(30);
            RID ROWID;
            X number;
            updt_stmt varchar2(300);
        BEGIN
          BEGIN
            TNAME := c.TNAME;
            CNAME := c.CNAME;
            RID   := c.RID;                
            DBMS_OUTPUT.PUT_LINE( TNAME || '=>' || CNAME);
            updt_stmt := 'UPDATE ' || TNAME || ' SET ' || CNAME || ' = ''123'' WHERE  ROWID   like ''%' || RID || '%''';                
            EXECUTE IMMEDIATE updt_stmt;
          EXCEPTION
            WHEN OTHERS THEN
            DBMS_OUTPUT.PUT_LINE('ERROR');
          END;
        END;
    END LOOP;
END;

Answer 1

未经测试，但我认为您可以首先尝试使用 FOR UPDATE 锁定记录，并通过指定 NOWAIT 导致其他事务处于活动状态会导致失败。 然后，您可以捕获此异常并跳过处理。 下面是一个未经测试的示例：

DECLARE
  x ROWID;
  resource_busy EXCEPTION;
  PRAGMA EXCEPTION_INIT(resource_busy,
                        -00054);
BEGIN
  FOR c IN (SELECT *
              FROM table_one a)
  LOOP
    DECLARE
      tname     VARCHAR2(30);
      cname     VARCHAR2(30);
      rid       ROWID;
      x         NUMBER;
      updt_stmt VARCHAR2(300);
    BEGIN
      BEGIN
        tname := c.tname;
        cname := c.cname;
        rid   := c.rid;
        dbms_output.put_line(tname || '=>' || cname);
        BEGIN
          EXECUTE IMMEDIATE 'SELECT rowid FROM ' || tname ||
                            ' WHERE rowid = :x FOR UPDATE NOWAIT'
            INTO x
            USING rid;
        EXCEPTION
          WHEN resource_busy THEN
            dbms_output.put_line('Record locked; try again later.');
            CONTINUE;
        END;
        updt_stmt := 'UPDATE ' || tname || ' SET ' || cname ||
                     ' = ''123'' WHERE  ROWID   like ''%' || rid || '%''';
        EXECUTE IMMEDIATE updt_stmt;
      EXCEPTION
        WHEN OTHERS THEN
          dbms_output.put_line('ERROR');
      END;
    END;
  END LOOP;
END;