未发现 ID 为"crashlytics"的插件 Android 工作室最新插件的问题

Question

对于以下gradle构建配置，我面临错误:(11,0)id为'crash '的插件未发现错误。

buildscript {
    repositories {
        maven { url 'http://download.crashlytics.com/maven' }
    }
    dependencies {
    }
}
apply plugin: 'android'
apply plugin: 'crashlytics'
apply plugin: 'hugo'

repositories {
    maven { url 'http://download.crashlytics.com/maven' }
}


android {
    compileSdkVersion 19
    buildToolsVersion '20.0.0'
    defaultConfig {
        applicationId "com.wiznsystems.android"
        minSdkVersion 15
        targetSdkVersion 19
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            runProguard false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}
dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile files('libs/smartconfiglib.jar')
    // You must install or update the Support Repository through the SDK manager to use this dependency.
    compile 'com.crashlytics.android:crashlytics:1.+'
    compile 'com.android.support:support-v4:19.+'
    compile 'com.google.android.gms:play-services:4.2.42'
    compile 'com.jakewharton.hugo:hugo-runtime:1.1.0'
    compile 'com.squareup.retrofit:retrofit:1.+'
    compile 'com.android.support:appcompat-v7:19.+'
    compile 'com.jakewharton:butterknife:5.+'
    compile 'de.greenrobot:eventbus:2.2.1'
    compile 'fr.avianey:facebook-android-api:+@aar'
    compile 'com.squareup.picasso:picasso:2.+'
    compile 'de.keyboardsurfer.android.widget:crouton:1.8.4'
    compile project(':apptentiveandroidsdk')
}

我做错了什么吗?或者是否有任何解决方法来构建它?

Answer 1

我也有同样的问题。我最终所做的便是将命令的顺序与Crashlytics所提供的内容结合在一起。我有个和你的类似的东西，但不管用。一旦它将其更改为文档的确切顺序，它就会工作。这是我现在的样子。希望这对你有所帮助。

buildscript {
  repositories {
      mavenCentral()
      maven { url 'http://download.crashlytics.com/maven' }
  }
  dependencies {
      classpath 'com.android.tools.build:gradle:0.12.+'
      classpath 'com.crashlytics.tools.gradle:crashlytics-gradle:1.+'
  }
}
apply plugin: 'android'
apply plugin: 'crashlytics'
repositories {
  mavenCentral()
  maven { url 'http://download.crashlytics.com/maven' }
}
dependencies {
  compile fileTree(dir: 'libs', include: ['*.jar'])
  compile 'com.android.support:appcompat-v7:19.+'
  compile 'com.android.support:support-v4:19.0.+'
  compile 'com.squareup.picasso:picasso:2.3.2'
  compile 'com.joanzapata.android:android-iconify:1.0.6'
  compile 'com.github.hotchemi:android-rate:0.3.1'
  compile 'com.loopj.android:android-async-http:1.4.5'
  compile 'com.github.satyan:sugar:1.3'
  compile 'com.crashlytics.android:crashlytics:1.+'
}
android {
  compileSdkVersion 19
  buildToolsVersion "20"
defaultConfig {
    minSdkVersion 14
    targetSdkVersion 19
    versionCode 1
    versionName "1.0"
}
buildTypes {
    release {
        runProguard false
        proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
    }
}
}

Answer 2

尝试通知类路径依赖:

buildscript {
    repositories {
        maven { url 'http://download.crashlytics.com/maven' }
    }
    dependencies {
        classpath 'com.crashlytics.tools.gradle:crashlytics-gradle:1.+'
    }
}

Answer 3

在与这个错误斗争了几个小时后，我最终删除了"。在我的主目录下的Gradle"文件夹，问题消失了!所以，如果你遇到这个问题，试着先删除。gradle文件夹，然后重新构建你的项目。