XPath 中总和和乘积的聚合函数

Question

类似于这个问题(http://stackoverflow.com/q/1333558/948404(，我想使用 XPath 来计算结构中乘积的总和：

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

是否有 XPath 表达式来计算每个项目value和quantity的乘积之和？

更新：该解决方案必须与PHP的XSLTProcessor类一起使用，这意味着它可能必须符合XSLT 1.0。这就是为什么我还没有接受使用 XSLT 2.0 的两个可能正确的答案。我既无法在我的PHP实现中测试它们，也无法在我的浏览器中测试它们，也无法在w3schools的Tryit编辑器[1]中测试它们。不好意思！

1. http://w3schools.com/xsl/tryxslt.asp?xmlfile=cdcatalog&xsltfile=cdcatalog

Answer 1

使用以下 XPath 2.0 表达式：

sum(/items/item/(value * quantity))

下面是作为验证的 XSLT 2.0 转换：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:sequence select="sum(/items/item/(value * quantity))"/>
    </xsl:template>
</xsl:stylesheet>

在提供的 XML 文档上应用此转换时：

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

计算 XPath 表达式，并输出此计算的结果：

8

解释：

在 XPath 2.0 中，位置步骤是合法

的

/(expression) ，

甚至

/someFunction(argumentList)

---

二、XSLT 1.0 解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:template match="/*">
  <xsl:call-template name="sumProducts">
    <xsl:with-param name="pNodes" select="item"/>
  </xsl:call-template>
 </xsl:template>
 <xsl:template name="sumProducts">
   <xsl:param name="pNodes" select="/.."/>
   <xsl:param name="pAccum" select="0"/>
   <xsl:choose>
    <xsl:when test="not($pNodes)">
     <xsl:value-of select="$pAccum"/>
    </xsl:when>
    <xsl:otherwise>
     <xsl:call-template name="sumProducts">
      <xsl:with-param name="pNodes" select="$pNodes[position() >1]"/>
      <xsl:with-param name="pAccum" select=
      "$pAccum + $pNodes[1]/value * $pNodes[1]/quantity"/>
     </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档(如上(时，将再次生成所需的正确结果：

8

请注意：使用FXSL库很容易解决此类问题。要调用的模板是 transform-and-sum 。

Answer 2

试试这个：

<xsl:stylesheet version="2.0"xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:sequence select="sum(/items/item/(value * quantity))"/>
    </xsl:template>
</xsl:stylesheet>

Answer 3

基于这个建议 https://stackoverflow.com/a/1334165/948404 我想出了一个符合 XSLT 1.0 和 XPath 1.0 的解决方案，它们由 libxml/libxslt 实现，由 PHP 实现XSLTProcessor使用(感谢 @Dimitre Novatchev 的确认(。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/items">
        <xsl:call-template name="recursivesum">
            <xsl:with-param name="items" select="*" />
        </xsl:call-template>
    </xsl:template>
    <xsl:template name="recursivesum">
        <xsl:param name="items" />
        <xsl:param name="sum" select="0" />
        <xsl:variable name="head" select="$items[1]" />
        <xsl:variable name="tail" select="$items[position()>1]" />
        <xsl:variable name="thissum" select="$head/value * $head/quantity" />
        <xsl:choose>
            <xsl:when test="not($tail)">
                <xsl:value-of select="$sum+$thissum" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="recursivesum">
                    <xsl:with-param name="sum" select="$sum+$thissum" />
                    <xsl:with-param name="items" select="$tail" />
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:transform>