OpenglGL上的级联阴影贴图纹理访问错误

Question

我正在尝试实现级联阴影贴图，当我想访问我的截体的每个分区的相应深度纹理时，我有一个错误。

更具体地说，我的问题发生在我想要选择正确的阴影纹理时，如果我尝试下面的代码，我有一个像这张图一样的伪影，你正在看一个立方体的阴影，伪影是切割截锥边界之间的小点/正方形(红色代表近切，绿色代表远切)

uniform sampler2D   shadowMaps[10];         //GL_TEXTURE5
uniform float       cameraFrustumZPartitionning[10];
uniform int         cameraFrustumSize;
int getCSMlevel(float Z){
    for(int iZ = 0 ; iZ < cameraFrustumSize; ++iZ)
        if(Z < cameraFrustumZPartitionning[iZ])
            return iZ;
    return -1;
}

float ShadowCalculation(vec4 fragPosLightSpace[3], int shadowMapId, float NdotD) //WIP
{
    int csmLevel = getCSMlevel(ClipSpacePosZ);
    vec4 fragPosLS = fragPosLightSpace[csmLevel];
    vec3 projCoords = fragPosLS.xyz / fragPosLS.w;
    // Transform to [0,1] range
    projCoords = projCoords * 0.5 + 0.5;
    float closestDepth = 0.0;

    if(csmLevel == -1)
        return 0.0;
    closestDepth = texture(shadowMaps[csmLevel], projCoords.xy).r;
    return 1.0 - ((projCoords.z  > closestDepth)?1.0:0.0);
}

如果我尝试这段代码，一切都很好。

uniform sampler2D   shadowMaps[10];         //GL_TEXTURE5
uniform float       cameraFrustumZPartitionning[10];
uniform int         cameraFrustumSize;
int getCSMlevel(float Z){
    for(int iZ = 0 ; iZ < cameraFrustumSize; ++iZ)
        if(Z < cameraFrustumZPartitionning[iZ])
            return iZ;
    return -1;
}

float ShadowCalculation(vec4 fragPosLightSpace[3], int shadowMapId, float NdotD) //WIP
{
    int csmLevel = getCSMlevel(ClipSpacePosZ);
    vec4 fragPosLS = fragPosLightSpace[csmLevel];
    vec3 projCoords = fragPosLS.xyz / fragPosLS.w;
    // Transform to [0,1] range
    projCoords = projCoords * 0.5 + 0.5;
    float closestDepth = 0.0;

    if(csmLevel == 0)
        closestDepth = texture(shadowMaps[0], projCoords.xy).r;
    else if(csmLevel == 1)
        closestDepth = texture(shadowMaps[1], projCoords.xy).r;
    else if(csmLevel == 2)
        closestDepth = texture(shadowMaps[2], projCoords.xy).r;
    else
        return 0.0;
    return 1.0 - ((projCoords.z  > closestDepth)?1.0:0.0);
}

在GLSL中，我们能够使sampler2D数组，并通过访问具有变量的数组获得正确的数组，或者我在这里犯了一个巨大的错误?

Answer 1

From GLSL 4.50 spec:

当在shader中聚合成数组时，采样器只能使用动态统一的整型表达式进行索引，否则结果是未定义的。

这意味着所有的片段着色器调用应该计算使用相同的索引。你的第一个代码显然不能满足这个要求。在第二个版本中，执行是显式发散的，因此对于每个代码路径，索引是动态统一的。

编辑:因为你的阴影地图可能是相同的大小，你可以使用数组纹理代替。(数组纹理不是采样器的数组)