好吧，我已经试着重写这个Bison语法三次了，并且一直在运行shift/reduce和reduce/reduce冲突。我试图解析的语法如下。｛…｝中的项用于其中一个。[…]中的项目是可选的。
CONSTANT constant-name constant-class
constant-class = { EQUALS expression numeric-options }
{ EQUALS STRING string string-options }
numeric-options = [ PREFIX prefix-string ]
[ TAG tag-string ]
[ COUNTER #local-name ]
[ TYPENAME type-name ] ;
string-options = [ PREFIX prefix-string ]
[ TAG tag-string ] ;
CONSTANT (constant-name,...) EQUALS expression
[ INCREMENT expression ]
[ PREFIX prefix-string ]
[ TAG tag-string ]
[ COUNTER #local-name ]
[ TYPENAME type-name ];
CONSTANT constant-name EQUALS expression,
.
.
.
;
CONSTANT (constant-name,...) EQUALS expression,
.
.
.
;
我对让最后三个都工作有意见。我可以让他们中的任何一个工作，但不是所有的4个。我现在有一个转变/减少和一个减少/减少冲突。我的语法如下：
constant
: SDL_K_CONSTANT constant_style ';'
;
constant_style
: constant_name constant_class
| constant_list
| constant_set
;
constant_name
: sdl_name
;
constant_class
: SDL_K_EQUALS sdl_decimal
| SDL_K_EQUALS SDL_K_STRING sdl_string
;
constant_names
: constant_name
| constant_names ',' constant_name
| '(' constant_names ')'
;
names_equal
: constant_names SDL_K_EQUALS sdl_decimal
;
constant_list
: names_equal
;
constant_set
: names_equal
| constant_set ',' names_equal
;
我认为这些名称是自我记录的(至少你应该能够理解类型)。如有任何帮助，我们将不胜感激。我有一种感觉，我要么简化得太多，要么不够。
注意：我想好了如何编辑我的帖子，删除了选项，并将SDL_K_COMMA和SDL_K_SEMI更改为"，"one_answers"；"，分别地
谢谢。
以下是一些应该解析的示例：
CONSTANT block_node_size EQUALS 24;
CONSTANT Strcon EQUALS STRING "This is a string constant" PREFIX Jg$
#block_size = 24;
CONSTANT block_node_size EQUALS #block_size;
CONSTANT
xyz EQUALS 10,
alpha EQUALS 0,
noname EQUALS 63;
CONSTANT
(zyx, nameless) EQUALS 10,
(beta) EQUALS 1,
gamma EQUALS 42;
CONSTANT (
bits,
bytes,
words,
longs,
quads,
octas
) EQUALS 0 INCREMENT 1 PREFIX ctx$;
CONSTANT
(bad_block,bad_data,,,,
overlay,rewrite) EQUALS 0 INCREMENT 4;
CONSTANT (pli,c,bliss,macro)
EQUALS 4 INCREMENT 4 PREFIX lang$
COUNTER #lang;
CONSTANT (basic,pascal,fortran)
EQUALS #lang + 4 INCREMENT 4 PREFIX lang$;
我希望这能有所帮助。
BTW：这是这个的EBNF(有点)：
/*
* Define the CONSTANT construct (Left out Expression).
*/
Str ::= """ Printable* """
Name ::= "$" | "_" | [A-Za-z] ("$" | "_" | [A-Z0-9a-z])*
Names ::= Name | ("(" Name ("," Name )* ")")
Constant_class ::= "EQUALS" (Expression Numeric_options | "STRING" Str
String_options)
String_options ::= Prefix? Tag?
Numeric_options ::= String_options Counter? Typename? Radix?
Increment_options ::= Increment? Numeric_options
Constant_list ::= Names "EQUALS" Expression Increment_options
Constant_set ::= Names Equals Expression
("," Names "EQUALS" Expression)*
Constant ::= "CONSTANT" (Name Constant_class | Constant_list |
Constant_set) ";"?
Prefix ::= "PREFIX" Str
Tag ::= "TAG" Str
Radix ::= "RADIX" ("DEC" | "OCT" | "HEX")
Counter ::= "COUNTER" Variable
Increment ::= "INCREMENT" Expression
Typename ::= "TYPENAME" Name
我想就是这样。
我很难理解你到底在做什么，所以我做了一些假设，并在下面提供了一些替代方案。我希望它能接近。
基本问题是语法规范中的歧义。其中一个可能只是一个错误：根据您的模板，EQUAL的左手边似乎是一个单独的name，或者是由括号包围的name的逗号分隔列表。然而，您的语法允许使用逗号分隔的name列表，列表中的第一项(或唯一一项)可能是带括号的名称列表：
constant_names
: constant_name
| constant_names ',' constant_name
| '(' constant_names ')
这将与a、a, b、(a, b)、(a, b), c和(a, b), c, d相匹配。但是，我认为只有第一个和第三个是真正的意图。
无论如何，你有两个产品：
constant_style
: constant_name constant_class
| constant_list
对于第一个，我们有：
constant_class
: SDL_K_EQUALS sdl_decimal
而对于第二个，我们有：
constant_list: names_equal
names_equal
: constant_names SDL_K_EQUALS sdl_decimal
由于constant_name可以匹配单个name，因此有两种不同的方式来匹配answer = 42，这将不可避免地导致解析冲突。
但answer = 42还有另一种可能的解析：
constant_set
: names_equal
所以，让我们从简化所有这些东西开始，然后我们也许可以回到你最初的目标。这个想法是考虑语法相似的一切：
constant-stmt : "CONSTANT" clause-list ';'
clause-list : clause | clause-list ',' clause
clause : left-hand-side "EQUALS" right-hand-side
left-hand-side : name | '(' name-list ')'
name-list : name | name-list ',' name
right-hand-side: expression /* See below */
我希望这一切都足够简单易懂。
但我们可以从原文中看到(至少在某些情况下)，right-hand-side的选项比上面的片段中出现的要多得多。仅仅将其他语法添加到right-hand-side中是微不足道的。然而，其意图似乎是，只有在只有一个条款的情况下，这些额外选项才可用。在这种情况下，我们可以这样做：
constant-stmt : "CONSTANT" constant-body ';'
constant-body : complex-clause | clause-list
clause-list : clause | clause-list ',' clause
clause : left-hand-side "EQUALS" right-hand-side
right-hand-side: expression
complex-clause : left-hand-side "EQUALS" complex-rhs
complex-rhs : expression numeric-options
| "STRING" string-literal string-options
但不幸的是，由于numeric-options可能是空的，所以expression将同时匹配right-hand-side和complex-right-hand-side，所以这又回到了模糊状态。
在实践中，这种模糊性并不重要。作为CONSTANT声明中的唯一声明或作为此类声明列表之一的声明name EQUALS expression之间没有语义差异。因此，一种可能性是忽略由此产生的reduce/reduce冲突，可能是将%expect 1放入文件中。但这真的不太愉快。因此，我们将努力消除这个问题。
一种方法是坚持第一CCD_ 23具有至少一个CCD_。但这真的很烦人。首先，我们必须创建另一个子句类型——first-complex-clause或类似的类型——其次，我们必须写出至少存在一个选项的要求。
作为一个更简单的替代方案，我们可以只要求clause-list至少有两个clause，而不是只有一个。由于每个clause也可以匹配complex-clause，因此对clause-list的限制不会拒绝任何有效的clause。因此，这给了我们一个非常小的变化：
constant-body : complex-clause | clause-list
clause-list : clause ',' clause | clause-list ',' clause
附录
为了更准确地描述预期的语法(尽管它仍然缺少一些细节)，我修改了上面的语法，试图解析完整的语言。基本原则保持不变：定义由一个complex-clause(包括简单子句大小写)组成，或由至少两个简单clause组成的列表。唯一的区别是两种子句类型的定义方式。
我还修复了名称列表的生成，以便可以省略单个名称(例如(bad_block,bad_data,,,,overlay,rewrite))。如指南所示，列表必须至少包含一个名称，这会使语法稍微复杂一些。
我添加了指南中的选项(但没有添加EBNF中的额外选项)。我没有尝试处理省略的分号，这在指南中似乎是不允许的，尽管有一个没有尾随分号的声明示例。(这可能是拼写错误。)我添加了expression的定义，尽我所能。
我还添加了本地名称分配语句，因为它在测试文件中，而且很容易。
语法如下：
definition : %empty
| definition constant-defn
| definition local-assign
local-assign : LOCAL_NAME '=' expression ';'
constant-defn : "CONSTANT" constant-body ';'
constant-body : complex-clause | clause-list
clause-list : clause ',' clause | clause-list ',' clause
clause : name "EQUALS" expression
| name-list "EQUALS" expression
complex-clause : name "EQUALS" expression numeric-options
| name-list "EQUALS" expression list-options
| name "EQUALS" "STRING" string-literal string-options
| name-list "EQUALS" "STRING" string-literal string-options
name-list : '(' names ')'
names : optional-commas name | names ',' name | names ','
optional-commas : %empty | optional-commas ','
string-options : prefix-option tag-option
numeric-options : string-options counter-option typename-option
list-options : increment-option numeric-options
increment-option: %empty | "INCREMENT" expression
prefix-option : %empty | "PREFIX" prefix-name
tag-option : %empty | "TAG" tag-name
counter-option : %empty | "COUNTER" LOCAL_NAME
typename-option : %empty | "TYPENAME" name
expression : '-' expression %prec UNOP
| expression '*' expression
| expression '/' expression
| expression '+' expression
| expression '-' expression
| expression '@' expression
| expression '&' expression
| expression '!' expression
| '(' expression ')'
| INTEGER
| IDENT
| LOCAL_NAME
name : IDENT | QUOTED_IDENT
prefix-name : IDENT | QUOTED_NULL | QUOTED_IDENT
tag-name : IDENT | QUOTED_NULL | QUOTED_IDENT | QUOTED_TAG
string-literal : QUOTED_NULL | QUOTED_IDENT | QUOTED_TAG | QUOTED_STRING
你会看到，我添加了对各种类型的带引号字符串的区分，这样就可以处理(大多数)带引号字符串可能出现的不同上下文。正如指南中所示，我没有将最多4个字符的带引号字符串用作整数常量，因为我没有及时注意到这一点，也因为我无法通过简短的阅读来判断其目的是否是在名称必须带引号的表达式中允许常量(因为名称与关键字冲突)；在这种情况下，在我看来，引用四个或更少字符的名字是有歧义的。
如果不清楚歧视是如何运作的(可能不是)，下面是附带的弹性定义：
id [[:alpha:]$_][[:alnum:]$_]*
%%
[[:space:]]+ ;
CONSTANT { return K_CONSTANT; }
COUNTER { return K_COUNTER; }
EQUALS { return K_EQUALS; }
INCREMENT { return K_INCREMENT; }
PREFIX { return K_PREFIX; }
STRING { return K_STRING; }
TAG { return K_TAG; }
TYPENAME { return K_TYPENAME; }
[#]{id} { yylval.str = strndup(yytext, yyleng); return LOCAL_NAME; }
{id} { yylval.str = strndup(yytext, yyleng); return IDENT; }
["]{id}["] { yylval.str = strndup(yytext+1, yyleng-2); return QUOTED_IDENT; }
["]["] { yylval.str = strndup(yytext+1, yyleng-2); return QUOTED_NULL; }
["][[:alnum:]$_]+["] { yylval.str = strndup(yytext+1, yyleng-2); return QUOTED_TAG; }
["][[:print:]]+["] { yylval.str = strndup(yytext+1, yyleng-2); return QUOTED_STRING; }
[[:digit:]]+ { yylval.dec = strtoul(yytext, 0, 0); return INTEGER; }
. { return *yytext; }
我做了一个相当不充分的测试，用OP末尾的定义运行它(尽管我在第二行添加了一个尾随的;)。我实际上并没有检查解析树是否正确，但它确实通过了解析器。