如何使能够在Netlogo中保存其他海龟ID?

Question

这是我想要做的：

1. 我想要一个由3 只海龟组成的团队。

2. 所有海龟都需要将自己的ID和队友ID存储在名为队友ID的变量中。(想象一下你想创建一个组，你会把你的名字和你朋友的名字放在一个列表中，这就是为什么这个变量需要存储ownID，我不擅长解释事情。

3. 不仅仅是显示(agentset,3 turtles)，我需要他们能够显示所有队友的ID。

4. 在他们聚集了所有 3 名成员后，他们将获得teamID.

这里的问题是我不知道如何让这些海龟将自己的 ID 和队友 ID 存储在名为 teammatesID 的变量中。在一个小组中，他们应该有3 个不同的成员。这些队友不应该来自同一个小组。以及如何给他们teamIDafter他们得到所有成员。

这是我的编码：

global
[ teamID]
turtles-own
[
myID
teammatesID
]
to setup
clear-all
set-default-shape turtles "arrow"
create-turtles 10
ask turtles [ set myID who]
reset-ticks
setup-group
end
to setup-group
set teamID []
let agent one-of other turtles
let  nearestNeighbor one-of other turtles in-radius 1 
set teamID = 0
ask agent with [ teammatesID < 3]
[ ask nearestNeighbor with [teammatesID < 3]
[ ;set teammatesID = myID ; here is the problem, I need to make sure they did not save the same turtle in one group.
show teammatesID]]
ask agent with [teammatesID > 3]
set teamID fput teamID teamID
end

感谢您在这里抽出额外的时间。谢谢。

Answer 1

如果团队是随机的，我认为你不需要为此循环，因为无论如何ask都会以随机顺序召唤海龟。

我认为您仍然应该在这里使用代理集，因为它使某些事情变得更容易。例如，一旦海龟知道他们的(agentset,3 turtles)，你可以很容易地查询该代理集的myID或你所追求的任何变量。

我不完全清楚teamID的目的，所以我可能在这里偏离了基础，但我认为如果每组三只海龟的teamID都是唯一的，你不希望它作为一个全局变量。您可能还希望它是一个turtles-own变量。

下面是一个包含上述想法的示例。通过此设置：

turtles-own [ myteamset teamID myID teammatesID ]
to setup 
ca
crt 10 [
set myID who
set myteamset nobody 
set teammatesID [ ]
]
setup-groups
print remove-duplicates [teammatesID] of turtles
print sort [teamID] of turtles
reset-ticks
end

和setup-groups程序(更多细节在评论中(：

to setup-groups
ask turtles [
; If you don't have a team yet
if myteamset = nobody [
; Make a temporary agent-set out of all other turtles that
; are also not yet part of a team
let possible-teammates other turtles with [ myteamset = nobody ]
; If there are at least two more turtles, make a new team:
ifelse count possible-teammates > 1 [
; Make a team out of myself and two possible teammates
set myteamset ( turtle-set self n-of 2 possible-teammates )
; Make a temporary variable to pass on to my entire team
; (yourself included) for the team ids and the team members.
; Also, assign a random teamID to the whole team
let ids sort [myID] of myteamset
let teammmembers myteamset
let tempteam random 1000
ask myteamset [
set teammatesID ids
set myteamset teammmembers
set teamID tempteam
]
] [
; If there aren't enough turtles to form a new team, 
; print a warning to the console.
show "Not enough turtles to make a new team!"
]
]
]
end

让我知道这是否是你所追求的，希望它有所帮助。

编辑 - 根据您的评论：

要获取连续的团队编号，您可以使用一个简单的计数器，该计数器被分配给团队，然后递增到下一个 - 修改后的setup-groups如下所示：

to setup-groups
; Create a temporary variable to use as a counter
let teamCounter 1
ask turtles [
if myteamset = nobody [
let possible-teammates other turtles with [ myteamset = nobody ]
ifelse count possible-teammates > 1 [
set myteamset ( turtle-set self n-of 2 possible-teammates )
let ids sort [myID] of myteamset
let teammmembers myteamset
; Assign the current teamCounter as team number, then 
; increment it by one for the next team
let tempteam teamCounter
set teamCounter teamCounter + 1
ask myteamset [
set teammatesID ids
set myteamset teammmembers
set teamID tempteam
]
] [
show "Not enough turtles to make a new team!"
]
]
]
end

第二个问题本身可能值得一个新问题，这取决于您希望获得的深度，但这里有一种非常简单的方法，您只需获得所有唯一的团队 ID，并让一只具有该 ID 的让他们的团队一起移动：

to move-in-groups
; Get the unique team IDs
let teamNumbers remove-duplicates [teamID] of turtles 
; Get one member of each team to ask all members
; of its team (itself included) to move 
foreach teamNumbers [
tn ->
ask one-of turtles with [ teamID = tn ] [
let newHeading heading + random 60 - 30
if myteamset != nobody [
ask myteamset [
set heading newHeading
fd 1
]
]
]
]
end

编辑2：网络徽标5友好版本

to move-in-groups
; Get the unique team IDs
let teamNumbers remove-duplicates [teamID] of turtles
; Get one member of each team to ask all members
; of its team (itself included) to move
foreach teamNumbers [
ask one-of turtles with [ teamID = ? ] [
let newHeading heading + random 60 - 30
if myteamset != nobody [
ask myteamset [
set heading newHeading
fd 1
]
]
]
]
end

Answer 2

我同意 Luke 的观点，即处理团队最合适的方法是作为代理集，而不是复杂的标识符分配。这就是代码的样子。请注意，我还没有解决您问题的运动部分。

globals [max-teamsize]
turtles-own
[ teamID
teammates
]
to testme
clear-all
create-turtles 100
[ setxy random-xcor random-ycor
set teamID 0
set teammates nobody
]
set max-teamsize 3
setup-groups
reset-ticks
end
to setup-groups
; assign turtles to team by allocating a team number
let counter 1
ask turtles
[ if teamID = 0
[ set teamID counter
let potential-teammates turtles with [teamID = 0]
ask n-of min (list (max-teamsize - 1) (count potential-teammates)) potential-teammates
[ set teamID counter
]
set counter counter + 1
]
]
; store teammates as agentset of other turtles in team
ask turtles
[ set teammates other turtles with [teamID = [teamID] of myself]
]
end