递归绑定中的SML语法限制

Question

SML的递归绑定中似乎存在语法限制，我无法理解。在第二种情况下（见下面的来源），我没有遇到什么限制，而在第一种情况下使用自定义运算符时，我遇到了什么限制？

以下是我遇到这个问题的案例。当我想使用自定义运算符时，它会失败，正如注释中所解释的那样。在我测试SML源代码的主要SML实现中，只有Poly/ML接受它是有效的，而所有的MLton、MLKit和HaMLet拒绝了它。

错误消息让我很困惑。在我看来，最清楚的是来自HaMLet的错误消息，它抱怨"递归值绑定中的非法表达式"。

(* A datatype to pass recursion as result and to arguments. *)
datatype 'a process = Chain of ('a -> 'a process)
(* A controlling iterator, where the item handler is
 * of type `'a -> 'a process`, so that while handling an item,
 * it's also able to return the next handler to be used, making
 * the handler less passive. *)
val rec iter =
   fn process: int -> int process =>
   fn first: int =>
   fn last: int =>
      let
         val rec step =
            fn (i: int, Chain process) (* -> unit *) =>
               if i < first then ()
               else if i = last then (process i; ())
               else if i > last then ()
               else
                  let val Chain process = process i
                  in step (i + 1, Chain process)
                  end
      in step (first, Chain process)
      end
(* An attempt to set‑up a syntax to make use of the `Chain` constructor,
 * a bit more convenient and readable. *)
val chain: unit * ('a -> 'a process) -> 'a process =
   fn (a, b) => (a; Chain b)
infixr 0 THEN
val op THEN = chain
(* A test of this syntax:
 *   - OK with Poly/ML, which displays “0-2|4-6|8-10|12-14|16-18|20”.
 *   - fails with MLton, which complains about a syntax error on line #44.
 *   - fails with ML Kit, which complains about a syntax error on line #51.
 *   - fails with HaMLet, which complains about a syntax error on line #45.
 * The clearest (while not helpful to me) message comes from HaMLet, which
 * says “illegal expression within recursive value binding”. *)
val rec process: int -> int process =
  (fn x => print (Int.toString x) THEN
  (fn x => print "-"              THEN
  (fn x => print (Int.toString x) THEN
  (fn x => print "|"              THEN
   process))))
val () = iter process 0 20
val () = print "n"
(* Here is the same without the `THEN` operator. This one works with
 * all of Poly/ML, MLton, ML Kit and HaMLet. *)
val rec process =
   fn x =>
     (print (Int.toString x);
      Chain (fn x => (print "-";
      Chain (fn x => (print (Int.toString x);
      Chain (fn x => (print "|";
      Chain process)))))))
val () = iter process 0 20
val () = print "n"
(* SML implementations version notes:
 *   - MLton, is the last version, built just yesterday
 *   - Poly/ML is Poly/ML 5.5.2
 *   - ML Kit is MLKit 4.3.7
 *   - HaMLet is HaMLet 2.0.0 *)

---

更新

我可以解决这个问题，但仍然不理解。如果我去掉最外面的括号，它就会验证：

val rec process: int -> int process =
   fn x => print (Int.toString x) THEN
  (fn x => print "-"              THEN
  (fn x => print (Int.toString x) THEN
  (fn x => print "|"              THEN
   process)))

代替：

val rec process: int -> int process =
  (fn x => print (Int.toString x) THEN
  (fn x => print "-"              THEN
  (fn x => print (Int.toString x) THEN
  (fn x => print "|"              THEN
   process))))

但为什么会这样呢？SML语法的微妙之处？它的合理性是什么？

Answer 1

这只是语言定义中的一个限制性太强的句子，它说：

对于rec中的每个值绑定"pat=exp"，expr的形式必须为"fnmatch。

严格来说，这不允许使用任何括号。在实践中，这很少是一个问题，因为您几乎总是使用fun声明语法。