访问空白，空或空字段的检查

Question

我的表格上有数十个字段。

字段是文本框和组合框的组合。我正在尝试找出一个单个按钮解决方案，以检查是否有空/空白/null字段。

如果找到了空白，我希望它显示一种表格；如果找不到，我希望它关闭当前表格。

我的代码在下面。

它成功地循环遍历所有字段，并在找到空白/空/空字段时显示一个表单，但是当（只有）没有空白/空/空的时，我不知道如何关闭表单表格上的空字段。

Private Sub Command146_Click()
    Dim ctl As Control
    With Me
        For Each ctl In .Controls
            If ctl.ControlType = acComboBox Or ctl.ControlType = acTextBox Then
                If Len(ctl.Value & "") = 0 Then
                    DoCmd.OpenForm "PopMissingData"
                    Exit For
                End If ' Value
            End If ' ControlType
        Next
    End With
End Sub

Answer 1

只需检查控制对象是否已"耗尽"：

Private Sub Command146_Click()
    Dim ctl As Control
    With Me
        For Each ctl In .Controls
            If ctl.ControlType = acComboBox Or ctl.ControlType = acTextBox Then
                If Len(ctl.Value & "") = 0 Then
                    Exit For
                End If ' Value
            End If ' ControlType
        Next
    End With
    If ctl Is Nothing Then
        ' All controls validated.
        DoCmd.Close acForm, Me.Name
    Else
        ' Open the other form.
        ' ctl will hold the non-validated control.
        DoCmd.OpenForm "PopMissingData"
    End If
End Sub