as3AirforAndroid下载和保存远程文件

Question

下面的代码使用as3 Air For Android从服务器下载mp3到您的手机。我想稍后在应用程序中使用这些文件，所以我有以下问题：

如何将文件保存到android应用程序中的特定文件夹，而不是打开一个框供用户选择位置

import flash.net.FileReference;
/// It can be an mp3,jpg, png, etc... just change the url
/// and the extension name. nice huh?
var yourFileLocation = "http://YourWeb.com/YourSong.mp3";
var yourFileName = "YourSong.mp3";
var daFile:FileReference = new FileReference();
daFile.download(new URLRequest(yourFileLocation), yourFileName);

当它开始、停止和进展时，监控这个进度也会很好，但我认为eventListener可能会处理这个问题。

Answer 1

以下代码从远程url下载mp3并创建一个名为.007的文件夹（您可以更改名称或添加多个或不添加文件夹）。然后保存到该位置。

import flash.filesystem.*;
/// Change the line below to point to your mp3 online
var urlString:String = "http://YourWebsite.com/YourSound.mp3";
var urlReq:URLRequest = new URLRequest(urlString);
var urlStream:URLStream = new URLStream();
var fileData:ByteArray = new ByteArray();
urlStream.addEventListener(Event.COMPLETE, loaded);
urlStream.load(urlReq);
function loaded(event:Event):void
{
    urlStream.readBytes(fileData, 0, urlStream.bytesAvailable);
    writeAirFile();
}
function writeAirFile():void
{ 
    // Change the folder path to whatever you want plus name your mp3
    // If the folder or folders does not exist it will create it.
    var file:File = File.userDirectory.resolvePath(".007/Yahoo.mp3");
    var fileStream:FileStream = new FileStream();
    fileStream.open(file, FileMode.WRITE);
    fileStream.writeBytes(fileData, 0, fileData.length);
    fileStream.close();
    trace("The file is written.");
}

p.S.记住在应用程序中使用ANDROID授予正确的许可

Answer 2

我到处寻找关于如何下载等的答案

我个人更喜欢的是从Greenshocks AS3库下载任何带有LoaderMax的文件（因为它是一个非常棒的轻量级加载程序，所以已经包含在我的大多数项目中了）

---

与其指定本地URL，不如指定远程URL。。让我给你看一些代码：

public function downloadTxtJpgMp3():void
{
    var queue:LoaderMax = new LoaderMax();
    emptyLoader();    //this emptys the loader from previous attempts to load any files
    queue.append( new DataLoader("http://www.70disco.com/lyrics/delegation_you_and_I.txt",{name:"test_txt" ,format:"text", estimatedBytes:4000})  );
    queue.append( new ImageLoader( "http://4.bp.blogspot.com/-WQ3uAvGdPS0/UOB_OPS6rcI/AAAAAAAAKkU/HYaXXHVHTqc/s1600/whatever-dude-whatever.jpg" , {name:"test_img" , estimatedBytes:77000, container:this, alpha:0, scaleMode:"proportionalInside"}) );
    queue.append( new MP3Loader( "http://nocturno.nsk.pt/otherpages/funny/mp3/2001-02/Cebola%20Mol/Cebola%20Mol%20-%20Satright%20No%20Chaser%20II.mp3" , {name:"test_mp3" , repeat:0, autoPlay: false}) );  
    queue.addEventListener(LoaderEvent.COMPLETE, onDownloadComplete);
    queue.load();
}

下面是COMPLETE事件的处理程序。你也可以有错误，失败，进程等你命名的处理程序。

protected function onDownloadComplete(event:LoaderEvent):void
{
    var objects:Array = event.currentTarget.content ;
    var firstObjectILoaded: String      //txt
    var secondObjectILoaded:Bitmap      //jpg
    var thirdObjectILoaded: Sound       //mp3
    // ContentDisplay is found within greenshock
    firstObjectILoaded = objects[0];
    secondObjectILoaded = ((objects[1] as ContentDisplay).rawContent as Bitmap)
    thirdObjectILoaded = objects[2];
    trace(firstObjectILoaded);
    thirdObjectILoaded.play();
}   

记住LoaderMax并不真正关心文件是本地还是远程，它只是将文件加载到内存中。。

---

从那时起，你可以决定是将其保存为文件，还是只使用它然后丢弃它

如果你想把它保存为一个文件，这里是如何：（下面的例子）

var str:String = File.applicationDirectory.nativePath;
//in iOs you can save on 4 different folder directories (according to apples rules)
// cache, temp, app support, and user documents (i don't cover this below)
appCache = new File(str +"/../Library/Caches");       //cache folder (in which you put files that you dont care being erased. the iOs might delete those files in case of low memory
appTempData = new File(str +"/../tmp");               //temp folder (just files you temporarily want to store
appData = new File(str +"/../Library/Application Support");      //any file your application NEEDS in order to operate, this can't be deleted by the os

var fr:FileStream = new FileStream();
fr.open(
    appTempData     //  appTempData or appCache or appData or userDocs
    .resolvePath("myCache.txt"),FileMode.WRITE); 
fr.writeUTFBytes("works");
fr.close(); 

---