我可以从同一个映射中的另一个值引用clojure hashmap值吗?

Question

我正试图想出一些方法让clojure hashmap中的值相互引用。从概念上讲，像这样:

(def m {:a 1 :b 5 :c (+ (:a m) (:b m))}  ;Implies (= (:c m) 6)

这当然不起作用，因为我循环引用了m。我可以输入

(def m {:a 1 :b 5 :c (fn [a b] (+ a b))})
((:c m) (:a m) (:b m)) ;=> 6

但是这并没有得到任何东西因为我仍然需要知道哪个a和b应该放到函数中。另一个尝试:

(def m {:a 1 :b 5 :c (fn [m] (+ (:a m) (:b m)))})
((:c m) m) ;=> 6

这有点好，因为我现在已经将函数内部化为一个映射，尽管没有特别这个映射。我可以试着用这样的东西来修复它

(defn new-get [k m]
  (let [v-or-fn (get m k)]
    (if (fn? v-or-fn) (v-or-fn m) v-or-fn)))
(def m {:a 1 :b 5 :c (fn [m] (+ (:a m) (:b m)))})
(new-get :a m) ;=> 1
(new-get :b m) ;=> 5
(new-get :c m) ;=> 6

我想这是我能做的最好的了。我错过了什么更聪明的东西吗?

Answer 1

忍不住写了一个宏:

(defmacro defmap [name m]
  (let [mm (into [] (map (fn [[k v]] `[~k (fn [~name] ~v)]) m))]
    `(def ~name
       (loop [result# {} mp# (seq ~mm)]
         (if (seq mp#)
           (let [[k# v#] (first mp#)]
             (recur (assoc result# k# (v# result#)) (rest mp#)))
           result#)))))
(defmap m [[:a 1]
           [:b 5]
           [:c (+ (:a m) (:b m))]])
;; m is {:a 1 :b 5 :c 6}

Answer 2

正如我在上面的评论中已经说过的，你可以使用let形式:

(def m 
  (let [a 1 b 5] 
    {:a a :b b :c (+ a b)}))

如果您使用的值仅在m定义中已知，则应该没有问题。否则，您最好使用@ michael所示的函数参数。

注:顺便说一下，您可以自由地使用def中通常在clojure中使用的所有内容。此外，有时您可以自由地在其他形式中使用糖形式的let(尽管这个let使用的机制与通常的let形式不同):

(for [x (...) xs]
     :let [y (+ x 1)]
     ; ...

Answer 3

由于c是a和b的派生值，因此您最好定义一个生成此映射的函数:

 (defn my-map-fn [a b]
   {:a a :b b :c (+ a b)})
 (def my-map (my-map-fn 1 2))
 (:c my-map) ;;=> 3

Answer 4

我的看法是:

(defmacro let-map [& bindings]
  (let [symbol-keys (->> bindings (partition 2) (map first))] 
    `(let [~@bindings]
       (into {} ~(mapv (fn [k] [(keyword k) k]) symbol-keys)))))
;; if you view it as similar to let, when it's more complicated:
(let-map
  a 1
  b 5
  c (+ a b)) ; => {:a 1, :b 5, :c 6}
;; if you see it as an augmented hash-map, when it's simple enough:
(let-map a 1, b 5, c (+ a b)) ; => {:a 1, :b 5, :c 6}