限制功能签名，同时在朱莉娅(Julia)中使用前卫

Question

我试图在库中使用前向diff，几乎所有功能都仅限于浮动。我想概括这些函数签名，以便可以使用远前诊断，同时仍具有足够的限制，因此功能仅采用数字值而不是诸如日期之类的东西。我有很多具有相同名称但不同类型的功能(即将"时间"作为float或具有相同功能名称的日期的函数(，并且不想在整个过程中删除类型的预选赛。

最小工作示例

using ForwardDiff
x = [1.0, 2.0, 3.0, 4.0 ,5.0]
typeof(x) # Array{Float64,1}
function G(x::Array{Real,1})
    return sum(exp.(x))
end
function grad_F(x::Array)
  return ForwardDiff.gradient(G, x)
end
G(x) # Method Error
grad_F(x) # Method error
function G(x::Array{Float64,1})
    return sum(exp.(x))
end
G(x) # This works
grad_F(x) # This has a method error
function G(x)
    return sum(exp.(x))
end
G(x) # This works
grad_F(x) # This works
# But now I cannot restrict the function G to only take numeric arrays and not for instance arrays of Dates.

是否有一种方法可以重新函数以仅采用数字值(INT和Floats(，以及远前野士使用但不允许符号，日期等的任何双重数字结构。

Answer 1

ForwardDiff.Dual是抽象类型Real的子类型。但是，您遇到的问题是朱莉娅的类型参数是不变的，而不是协变量的。然后，以下返回false。

# check if `Array{Float64, 1}` is a subtype of `Array{Real, 1}`
julia> Array{Float64, 1} <: Array{Real, 1}
false

使您的功能定义

function G(x::Array{Real,1})
    return sum(exp.(x))
end

不正确(不适合您使用(。这就是为什么您会遇到以下错误。

julia> G(x)
ERROR: MethodError: no method matching G(::Array{Float64,1})

正确的定义应该是

function G(x::Array{<:Real,1})
    return sum(exp.(x))
end

，或者如果您以某种方式需要轻松访问数组的混凝土元素类型

 function G(x::Array{T,1}) where {T<:Real}
     return sum(exp.(x))
 end

您的grad_F功能也是如此。

您可能会发现阅读类型的朱莉娅文档的相关部分很有用。

---

您可能还需要为AbstractArray{<:Real,1}类型而不是Array{<:Real, 1}输入注释您的功能，以便您的功能可以使用其他类型的数组，例如StaticArrays，OffsetArrays等，而无需重新定义。

Answer 2

这将接受任何类型的数字参数的数组：

function foo(xs::AbstractArray{<:Number})
  @show typeof(xs)
end

或：

function foo(xs::AbstractArray{T}) where T<:Number
  @show typeof(xs)
end

如果您需要参考字体功能中的类型参数T。

x1 = [1.0, 2.0, 3.0, 4.0 ,5.0]
x2 = [1, 2, 3,4, 5]
x3 = 1:5
x4 = 1.0:5.0
x5 = [1//2, 1//4, 1//8]
xss = [x1, x2, x3, x4, x5]
function foo(xs::AbstractArray{T}) where T<:Number
  @show xs typeof(xs) T
  println()
end
for xs in xss
  foo(xs)
end

输出：

xs = [1.0, 2.0, 3.0, 4.0, 5.0]
typeof(xs) = Array{Float64,1}
T = Float64
xs = [1, 2, 3, 4, 5]
typeof(xs) = Array{Int64,1}
T = Int64
xs = 1:5
typeof(xs) = UnitRange{Int64}
T = Int64
xs = 1.0:1.0:5.0
typeof(xs) = StepRangeLen{Float64,Base.TwicePrecision{Float64},Base.TwicePrecision{Float64}}
T = Float64
xs = Rational{Int64}[1//2, 1//4, 1//8]
typeof(xs) = Array{Rational{Int64},1}
T = Rational{Int64}

您可以在此处运行示例代码：https：//repl.it/@salchipapa/restricting-function-function-signatures-in-julia