在Arduino上执行多个函数/命令

Question

我正在使用RFduino和一个iOS应用程序来控制一些RGB led。

这是我如何发送字符串命令到模块:

- (IBAction)fadeButtonPressed:(id)sender {
    [rfduino send:[@"fade" dataUsingEncoding:NSUTF8StringEncoding]];
}

这些命令在RFduino端返回的很好:

void RFduinoBLE_onReceive(char *data, int len) {
  if (strncmp(data, "fade", 4) == 0) {
    // begin fading chosen LED colour
  }
}

在Arduino上执行多个函数有更好的方法吗?在我看来，应该有更好的方法来做我正在努力做的事情。

最初，例如，我得到一个问题，其中"褪色"字符串返回为"fadek"，所以我使用strncmp(data, "fade", 4)而不是strcmp(data, "fade")，这解决了这个问题。

我想我希望有一种方法来清理我的代码，也许可以更容易地根据返回的字符串引入新的功能。

我想要能够做的功能是控制RGB颜色，然后褪色或闪烁特定选择的颜色。

如果我想引入更快的闪烁呢?与其设置另一个命令整数并添加另一个条件，还有更简洁的方法吗?

颜色的选择是通过在我的iOS应用程序中选择色轮来设置的。这工作得很好。问题是，闪烁和褪色不会闪烁/褪色所选的颜色(command 0)。

这是我到目前为止的整个草图:

#include <RFduinoBLE.h>
// Pin 2 on the RGB LED.
int rgb2_pin = 2; // red
int rgb3_pin = 3; // green
int rgb4_pin = 4; // blue
int brightness = 0;
int fadeAmount = 5;
// Command properties.
int command = 0;
void setup() {
  // debug output at 9600 baud
  Serial.begin(9600);
  // Setup the LEDs for output.
  pinMode(rgb2_pin, OUTPUT);
  pinMode(rgb3_pin, OUTPUT);
  pinMode(rgb4_pin, OUTPUT);
  // This is the data we want to appear in the advertisement
  // (the deviceName length plus the advertisement length must be <= 18 bytes.
  RFduinoBLE.advertisementData = "rgb";
  // Start the BLE stack.
  RFduinoBLE.begin();
}
void loop() {
  if (command == 1) { // Fade in/out chosen colour.
    analogWrite(rgb2_pin, brightness);
    analogWrite(rgb3_pin, brightness);
    analogWrite(rgb4_pin, brightness);
    // Change the brightness for next time through the loop:
    brightness = brightness + fadeAmount;
    // Reverse the direction of the fading at the ends of the fade:
    if (brightness == 0 || brightness == 255) {
      fadeAmount = -fadeAmount ;
    }
    // Wait for 30 milliseconds to see the dimming effect
    delay(30);
  } else if (command == 2) { // Blink
    digitalWrite(rgb2_pin, HIGH);
    digitalWrite(rgb3_pin, HIGH);
    digitalWrite(rgb4_pin, HIGH);
    delay(200);
    digitalWrite(rgb2_pin, LOW);
    digitalWrite(rgb3_pin, LOW);
    digitalWrite(rgb4_pin, LOW);
    delay(200);
  }
}
void RFduinoBLE_onConnect() {}
void RFduinoBLE_onDisconnect() {}
void RFduinoBLE_onReceive(char *data, int len) {
  Serial.println(data);
  // Each transmission should contain an RGB triple.
  if (strncmp(data, "fade", 4) == 0) {
    command = 1;
  } else if (strncmp(data, "blink", 5) == 0) {
    command = 2;
  } else { // Change colour.
    // Reset other functions.
    command = 0;
    if (len >= 3) {
      // Get the RGB values.
      uint8_t red = data[0];
      uint8_t green = data[1];
      uint8_t blue = data[2];
      // Set PWM for each LED.
      analogWrite(rgb2_pin, red);
      analogWrite(rgb3_pin, green);
      analogWrite(rgb4_pin, blue);
    }
  }
  Serial.println(command);
}

Answer 1

对于这类通信，我的方法是定义一个包含开始和停止字符(例如0x01和0x03)的协议，然后构建一个处理每个传入字节的状态机。

这样做的原因是它有助于纠正乱序字节和通信错误。在得到0x01之前可以忽略数据，而在得到0x03之前命令不会结束。如果您在预期之前得到0x03，那么您可以丢弃无效的数据包。

你目前的方法和这种技术的一个问题是，你正在发送8位数据的RGB命令-这可能与你的开始/结束字节冲突。将数据编码为2位十六进制不会有太大影响，所以你可以有一个像

这样的协议

• 0x01 -数据包
开始
• 1字节命令b=Blink, f=Fade, c=set color
• 6字节参数。对于命令c，这将是rgb的三对十六进制字符。对于b &如果它可以是2个字符的闪烁/褪色率和其他4个字节为0000占位符
• 0x03 -报文结束

然后你可以构建一个状态机-

1. 等待0x01。一旦你把它移到状态2
2. 等待一个有效的命令字节。如果你得到一个有效的一步移动到状态3。如果得到0x01，移回状态2。如果你得到其他字节移动到状态1
3. 等待6位十六进制数字。如果你得到0x01保持状态2。如果你得到的不是0-9 a-f返回状态1
4. 等待0x03。如果你得到它，然后处理完成命令并返回状态1。如果你得到0x01，就往回走状态2。如果你有其他的东西，移动到状态1

这不会编译，因为我没有Arduino在我面前，但你会使用这样的东西

int state;   //  Initialise this to 1 
char command;
string hexstring;
void RFduinoBLE_onReceive(char *data, int len) {
    for (int i=0;i<len;i++) {
        stateMachine(data[i]);
    }
}
stateMachine(char data) {

    switch (state) {
       case 1:
          if (data == 1) {
              state=2;
          }
          break;
       case 2:
          if (data=='b' || data== 'f' || data == 'c') {  // If we received a valid command
             command=data;                               // store it
             hexstring="";                               // prepare to receive a hex string
             state=3;
          } else if (data != 1) {    //Stay in state 2 if we received another 0x01
             state =1;
          }
          break;
       case 3:
          if ((data >='a' && data <='z') || (data >='0' && data <='9')) {
              hexstring=hexstring+data;     // if we received a valid hex byte, add it to the end of the string
              if (length(hexstring) == 6) {  // If we have received 6 characters (24 bits) move to state 4
                  state=4;
              }
          } else if (data == 1) {            // If we received another 0x01 back to state 2
             state =2;
          } else {
             state=1;                        // Anything else is invalid - back to look for 0x01
          }
          break;
     case 4:
         if (data == 3)                      // 0x03=valid terminator
         {
           processCommand(command,hexstring);  // We have a valid command message - process it
           state=1;
         } else if (data==1) {               // 0x01= start of new message, back to state 2
           state=2;
         } else {
           state=1;                          // anything else, back to look for 0x01
         }
         break;
     }
}