如何分析分隔字符串

Question

我有一个以下格式的分隔字符串：

1^^2^^3^^4^^5^^||1^^2^^3^^4^^5^^||

其中^^是列分隔符，|| 是行分隔符。我需要能够遍历每一行，然后遍历每一列，并将值存储在不同的变量中。我想知道如何使用 XSL 1.0 来完成它。任何形式的帮助将不胜感激

Answer 1

下面是

一个使用EXSLT str:split的基于模板的实现的示例：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common"
  xmlns:str="http://exslt.org/strings"
  exclude-result-prefixes="exsl str">
<xsl:import href="http://exslt.org/str/functions/split/str.split.template.xsl"/>
<xsl:output indent="yes"/>
<xsl:template match="data">
  <xsl:variable name="rows-rtf">
    <xsl:call-template name="str:split">
      <xsl:with-param name="string" select="."/>
      <xsl:with-param name="pattern" select="'||'"/>
    </xsl:call-template>
  </xsl:variable>
  <xsl:variable name="rows" select="exsl:node-set($rows-rtf)/token[normalize-space()]"/>
  <xsl:for-each select="$rows">
    <row>
      <xsl:variable name="cols-rtf">
        <xsl:call-template name="str:split">
          <xsl:with-param name="string" select="."/>
          <xsl:with-param name="pattern" select="'^^'"/>
        </xsl:call-template>
      </xsl:variable>
      <xsl:variable name="cols" select="exsl:node-set($cols-rtf)/token[normalize-space()]"/>
      <xsl:for-each select="$cols">
        <col><xsl:value-of select="."/></col>
      </xsl:for-each>
    </row>
  </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

输出

<row>
   <col>1</col>
   <col>2</col>
   <col>3</col>
   <col>4</col>
   <col>5</col>
</row>
<row>
   <col>1</col>
   <col>2</col>
   <col>3</col>
   <col>4</col>
   <col>5</col>
</row>
<row>
   <col>a</col>
   <col>b</col>
   <col>c</col>
   <col>d</col>
   <col>c</col>
</row>

对于输入示例

<root>
  <data>1^^2^^3^^4^^5^^||1^^2^^3^^4^^5^^||a^^b^^c^^d^^c</data>
</root>