在XSLT1.0中用前导零填充数字

Question

我们在XML中有一个数字，在一个大型XML文件中，这个数字最多可以达到3位，必须转换为固定长度的文本才能加载到另一个系统中。

我需要在输出（固定长度的文本）中用前导零将其填充到15的长度

示例：

 - 1 becomes   000000000000001
 - 11 becomes  000000000000011
 - 250 becomes 000000000000250

我试过这个：

<xsl:value-of select="substring(concat('000000000000000', msg:BankAccount/msg:Counter), 12, 15)"/>

在开始时得到15个零，并取子字符串，但我一定对子字符串犯了错误，因为在结果中我得到了

0000000000000000000000009LLOYDS BANK PLC
00000000000000000000000010LLOYDS BANK PLC

我也试过format-number，但它返回NaN

<xsl:value-of select="format-number(msg:BankAccount/msg:Counter, '000000000000000')"/>

返回"NaN"

那么我做错了什么，最好的方法是什么呢？

Answer 1

另一种方法是

substring(string(1000000000000000 + $x), 2)

Answer 2

我需要在输出（）中用前导零将其填充到15的长度

那就是

substring(
  concat('000000000000000', msg:BankAccount/msg:Counter), 
  string-length(msg:BankAccount/msg:Counter) + 1, 
  15
)

Answer 3

也可以使用字符串格式

<xsl:value-of select="format-number(msg:BankAccount/msg:Counter, '000000000000000')" />

一般来说：

<xsl:value-of select="format-number(number_you_would_like_to_padd, 'string_how_much_zeros_you_would like')" />

Answer 4

另一个选项是xsl:number。。。

<xsl:number value="number_to_format" format="000000000000001"/>

完整示例。。。

XML输入

<doc>
    <test>1</test>
    <test>11</test>
    <test>250</test>
</doc>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*"/>
  <xsl:template match="test">
    <xsl:number value="." format="000000000000001"/>
    <xsl:text>&#xA;</xsl:text>
  </xsl:template>
</xsl:stylesheet>

输出

000000000000001
000000000000011
000000000000250

Fiddle：http://xsltfiddle.liberty-development.net/pPzifpg

Answer 5

另一个需要考虑的选项。。。。

<xsl:apply-templates select="Groups/Group[@Name='TheSource']/Field[@Name='BankAccount']" />
<xsl:text>999999999999999</xsl:text>
<!-- uncomment below and comment above line to use without test number -->
<!-- <xsl:text>|</xsl:text> -->
<xsl:template match="Groups/Group[@Name='BankAcctFile']/Field[@Name='BankAccount']">
    <xsl:call-template name="padleft">
        <xsl:with-param name="padChar" select="'0'" />
        <xsl:with-param name="padVar" select="substring(current(),1,15)" />
        <xsl:with-param name="length" select="15" />
    </xsl:call-template>
</xsl:template>