我在'addons/math/misc/brent.ijs'中发现Brent方法作为副词的实现。我也想建立一个牛顿方法作为副词，但它比建立隐含动词要困难得多。
以下是牛顿迭代的显式版本：
newton_i =: 1 : '] - u % u d.1'
有这样的用法：
2&o. newton_i^:_ (1) NB. (-: 1p1) must be found
1.5708
2 o. 1.5708 NB. after substitution we get almost 0
_3.67321e_6
当然，为了方便起见：
newton =: 1 : 'u newton_i^:_'
什么是默认的等价物？
TL；DR
根据评论，一个简短的回答；与原始显式newton_i和newton的隐含等价物分别为：
n_i =: d.0 1 (%/@:) (]`-`) (`:6)
newton =: n_i (^:_)
一般来说，关于如何获得此类翻译的一些技巧可以在J论坛上找到。
施工
这里的关键见解是：（a）函数与其自身的"零阶导数"相同，（b）由于该语言面向数组的特性，我们可以同时计算J中函数的"零"阶导数和一阶导数。剩下的只是集邮。
在理想世界中，给定函数f，我们希望生成类似(] - f % f d. 1)的动词串。问题是，J中的隐性状语程序限制我们产生一个只提到输入函数（f）一次的动词。
因此，我们使用了一个狡猾的技巧：我们同时计算f的两个导数："第零"导数（这是一个恒等函数）和一阶导数。
load 'trig'
sin NB. Sine function (special case of the "circle functions", o.)
1&o.
sin d. 1 f. NB. First derivative of sine, sin'.
2&o.
sin d. 0 f. NB. "Zeroeth" derivative of sine, i.e. sine.
1&o."0
sin d. 0 1 f. NB. Both, resulting in two outputs.
(1&o. , 2&o.)"0
znfd =: d. 0 1 NB. Packaged up as a re-usable name.
sin znfd f.
(1&o. , 2&o.)"0
然后我们简单地在它们之间插入一个除法：
dh =: znfd (%/@) NB. Quotient of first-derivative over 0th-derivattive
sin dh
%/@(sin d.0 1)
sin dh f.
%/@((1&o. , 2&o.)"0)
sin dh 1p1 NB. 0
_1.22465e_16
sin 1p1 NB. sin(pi) = 0
1.22465e_16
sin d. 1 ] 1p1 NB. sin'(pi) = -1
_1
sin dh 1p1 NB. sin(pi)/sin'(pi) = 0/-1 = 0
_1.22465e_16
(%/@)位于znfd的右侧，因为J中的隐性状语编程是LIFO（即从左到右，其中"正常"J是从右到左）。
集邮
正如我所说，剩下的代码只是收集邮票，使用标准工具构建一个动词串，从原始输入中减去这个商：
ssub =: (]`-`) (`:6) NB. x - f(x)
+: ssub NB. x - double(x)
] - +:
-: ssub NB. x - halve(x)
] - -:
-: ssub 16 NB. 16 - halve(16)
8
+: ssub 16 NB. 16 - double(16)
_16
*: ssub 16 NB. 16 - square(16)
_240
%: ssub 16 NB. 16 - sqrt(16)
12
因此：
n_i =: znfd ssub NB. x - f'(x)/f(x)
最后，使用^:_的"应用到不动点"特性，我们得到了：
newton =: n_i (^:_)
沃伊拉。
newton_i =: 1 : '] - u % u d.1'
是半隐性的，因为隐性动词在与动词结合时产生（副词在结合时消失）。
newton_i2 =: 1 : '(] - u % u d.1) y'
完全明确的是，与动词绑定并不能解析副词。
+ 1 : 'u/'
+/
+ 1 : 'u/ y'
+（1:'u/y'）
使半隐性副词完全隐性并没有太大的重要性，因为这可能不会提高表现，而且它在副词区域内而不是在呼叫者中解决（完全显性副词的情况）也有同样的好处。