捕获音频会话事件

Question

我尝试编写一些可以监视音频会话的应用程序（就像SndVol一样）。我激活了IAudioSessionManager2，通过IAudioSessionEnumerator获取了当前音频会话的列表，并使用音频会话管理器中的RegisterSessionNotification方法注册了通知。但是，我的应用程序永远不会收到通知 OnSessionCreated（）。当然，我在这里阅读了类似的主题：通知未发送，IAudioSession通知任何人都有工作代码

我

仔细阅读了所有的答案，但我找不到我做错了什么。这是我的代码（德尔福）：

TDNAudioSessionManager = class(TDNUnknownObject, IAudioSessionNotification)
private
  FManager: IAudioSessionManager2;
  FList: TDNAudioSessionList;
  function IsManagerValid: Boolean;
protected
  procedure ActivateSessionManager(out AManager: IAudioSessionManager2);
  procedure GetCurrentSessions;
  // IAudioSessionNotification
  function OnSessionCreated(ANewSession: IAudioSessionControl): HRESULT; stdcall;
public
  constructor Create;
  destructor Destroy; override;
end;
constructor TDNAudioSessionManager.Create;
begin
  inherited Create;
  ActivateSessionManager(FManager);
  if IsManagerValid then
  begin
    FList := TDNAudioSessionList.Create;
    FManager.RegisterSessionNotification(Self);
    GetCurrentSessions;
   end;
 end;
destructor TDNAudioSessionManager.Destroy;
begin
  if IsManagerValid then
  begin
    FManager.UnregisterSessionNotification(Self);
    FManager := nil;
  end;
  FreeAndNil(FList);
  inherited Destroy;
 end;
function TDNAudioSessionManager.IsManagerValid: Boolean;
begin
  Result := Assigned(FManager);
end;
procedure TDNAudioSessionManager.GetCurrentSessions;
var
  AEnumerator: IAudioSessionEnumerator;
  ASession: IAudioSessionControl;
  ACount: Integer;
  I: Integer;
begin
  if IsManagerValid then
    if FManager.GetSessionEnumerator(AEnumerator) = S_OK then
    try
      AEnumerator.GetCount(ACount);
      for I := 0 to ACount - 1 do
      begin
        AEnumerator.GetSession(I, ASession);
        FList.Add(ASession);
      end;
    finally
      AEnumerator := nil;
    end;
end;
function TDNAudioSessionManager.OnSessionCreated(ANewSession: IAudioSessionControl): HRESULT;
begin
  FList.Add(ANewSession);
  Result := S_OK;
end;
procedure TDNAudioSessionManager.ActivateSessionManager(out AManager: IAudioSessionManager2);
var
  AEnumerator: IMMDeviceEnumerator;
  ADefault: IMMDevice;
  ARes: HRESULT;
begin
  AManager := nil;
  ARes := CoCreateInstance(CLSID_MMDeviceEnumerator, nil, CLSCTX_INPROC_SERVER, IID_IMMDeviceEnumerator, AEnumerator);
  if not ARes = S_OK then Exit;
  if AEnumerator.GetDefaultAudioEndpoint(eRender, eConsole,  ADefault) = S_OK then
  try
    ADefault.Activate(IID_IAudioSessionManager2, CLSCTX_INPROC_SERVER, nil, AManager);
  finally
    ADefault := nil;
  end;
end;
initialization
  CoInitializeEx(nil, COINIT_MULTITHREADED);
end.

注意：TDNUnknownObject 是实现 IUnknown 方法的类。

还有一个问题：应用程序关闭时音频会话发送什么事件？（在 SndVol 中，它已从列表中删除）。我尝试了OnSessionDisconnected，OnStateChanged（状态为AudioSessionExpire），但我的应用程序也从未收到它们。

提前感谢！

TDNUnknownObject：

TDNUnknownObject = class(TObject, IUnknown)
protected
  // IUnknown
  function _AddRef: Integer; stdcall;
  function _Release: Integer; stdcall;
  function QueryInterface(const IID: TGUID; out Obj): HRESULT; virtual; stdcall;
end;
function TDNUnknownObject._AddRef: Integer; stdcall;
begin
  Result := -1;
end;
function TDNUnknownObject._Release: Integer; stdcall;
begin
  Result := -1;
end;
function TDNUnknownObject.QueryInterface(const IID: TGUID; out Obj): HRESULT; stdcall;
begin
  if GetInterface(IID, Obj) then
    Result := S_OK
  else
    Result := E_NOINTERFACE;
end;

Answer 1

好吧，

我对此挠头..第一个问题出现了：为什么不使用 TInterfacedObject？节省了大量工作，并被证明可以正常工作。此对象派生自 IUnknown，并别名为 IInterface，并且完全按照您在此处尝试执行的操作。当然，您可以尝试编写自己的版本，但要注意：Delphi编译器将更加严格，因此您将很容易遇到双重实现和名称冲突等陷阱。编译器、链接器和调试器的行为可能因此而异常。

好的，来自MS的简短说明：确保应用程序通过在非 UI 线程中调用 CoInitializeEx（Nil， COINIT_MULTITHREADED） 来初始化具有多线程单元 （MTA） 模型的 COM。如果未初始化 MTA，则应用程序不会从会话管理器接收会话通知。运行应用程序用户界面的线程应初始化单元线程模型。

好了：您的初始化部分不正确。它应该是：

initialization
  CoInitializeEx(Nil,
                 COINIT_APARTMENTTHREADED);