我正在使用 VB6 网络浏览器，当用户单击WebBrowser链接的任何特定链接时，我需要打开一个 vb6 表单，例如
在 HTML 中
<html>
<head>
<body>
<a href="--show vb6 form--">Click To show VB6 Form2</a>
</body>
</html>
我不知道该怎么做。我想有时可以完成第三个文本文件，例如单击链接时会在文本文件中写入002这样的鳕鱼。
在vb表单中，计时器将每秒检查一次文件，当计时器检测到文件包含002时，它将显示表单。
可以用这种方法做到这一点吗？ 或者我可以排除的其他更短的东西？
选择一个更好的命名方案，例如：
<a href="#vb-showform2">Click To show VB6 Form2</a>
<a href="#vb-waffles">Waffles</a>
然后通过BeforeNavigate2事件拦截链接点击，查看网址，如果匹配#vb-*运行代码：
Private Sub WebBrowserCtrl_BeforeNavigate2(ByVal pDisp As Object, URL As Variant, Flags As Variant, TargetFrameName As Variant, PostData As Variant, Headers As Variant, Cancel As Boolean)
'// get #vb-XXX command from url
Dim pos As Long: pos = InStrRev(URL, "#vb-")
If pos Then
Cancel = True '// stop default navigation
URL = Mid$(URL, pos + 4)
Select Case LCase$(URL)
Case "showform2": Form2.Show
'...
Case "waffles": MsgBox "Waffles."
Case Else: MsgBox "Unknown Command " & URL
End Select
End If
End Sub
与其将表单名称放在href属性中，我相信更好的方法是设置自己的data attribute并使用它，在我看来，执行此类任务的方法要干净得多。
在我的示例中，在href标签内，我使用经典void(0)来阻止链接导航，否则指向 VB 表单的外部链接可能会破坏浏览器历史记录并产生意外结果。
要使用WebBrowser控件，您应该已经在 VB 项目中添加了对Microsoft Internet Controls的引用，接下来需要的是添加对Microsoft HTML Library的引用，即包含在mshtml.tlb文件中的类型库。
假设您的WebBrowser控件称为"WebBrowser1"，并且您有三个额外的窗体，分别称为"Form1"、"Form2"和"Form3"，在您放置WebBrowser控件的窗体中放置这段代码：
Private HTMLdoc As MSHTML.HTMLDocument
' Create a Web Page to test the navigation '
' You can skip this phase after your test are successfully executed '
Private Sub Form_Load()
Dim HTML As String
WebBrowser1.Navigate "about:blank"
HTML = "<html>"
HTML = HTML & "<title>Open a VB Form from a Link</title>"
HTML = HTML & "<body>"
HTML = HTML & "<a data-vb='Form1' href='javascript:void(0)'>Click To show Form1</a>"
HTML = HTML & "</br>"
HTML = HTML & "<a data-vb='Form2' href='javascript:void(0)'>Click To show Form2</a>"
HTML = HTML & "</br>"
HTML = HTML & "<a data-vb='Form3' href='javascript:void(0)'>Click To show Form3</a>"
HTML = HTML & "</br>"
HTML = HTML & "</body>"
HTML = HTML & "</html>"
WebBrowser1.Document.Write HTML
End Sub
' This will load and show the form specified in the data-vb attribute of the link '
Private Sub WebBrowser1_BeforeNavigate2(ByVal pDisp As Object, URL As Variant, Flags As Variant, TargetFrameName As Variant, PostData As Variant, Headers As Variant, Cancel As Boolean)
Dim frm As Form, FormName as String
If Not (WebBrowser1.Document Is Nothing) Then
Set HTMLdoc = WebBrowser1.Document
FormName = vbNullString & HTMLdoc.activeElement.getAttribute("data-vb")
If Not FormName = vbNullString Then
Set frm = Forms.Add(FormName)
frm.Show
End If
End If
End Sub
补充说明：
您可以通过以下方式获取单击链接的内容：
HTMLdoc.activeElement.toString
显然，对于我的测试页面中的所有链接，结果将是：
javascript:void(0)与 BeforeNavigate 事件的URL参数相同。
您可以从HTMLDocument获得但在BeforeNavigate事件中不可用的另一个有用信息是，例如：
HTMLdoc.activeElement.outerHTML
结果将是：
<A href="javascript:void(0)" data-vb="Form2">Click To show Form2</A>
要使用按钮而不是链接来执行此操作，请将按钮添加到文档中并添加一些javascript：
<input type="button" id="MyButton1_id" style="cursor: pointer" name=MyButton1 value="Show It!">
<SCRIPT LANGUAGE="VBScript">
Sub MyButton1_OnClick()
location.href = "event:button1_show"
End Sub
</SCRIPT>
然后在BeforeNavigate2事件中：
Public Sub webBrowser_BeforeNavigate2(ByVal pDisp As Object, URL As Variant, flags As Variant, TargetFrameName As Variant, PostData As Variant, Headers As Variant, Cancel As Boolean)
Select Case LCase$(URL)
Case "event:button1_show"
Cancel = True
Form2.Show
Case "event:other_stuff"
'other stuff to do, etc
End Select
End Sub