使用 Perl 模块时的最佳实践

Question

我基本上是模块的新手，我正在尝试在我的脚本中使用它们。 我找不到正确使用它们的正确方法，我希望您对此提出建议。

让我快速解释一下我想做什么：

我的脚本正在根据 XML 文件中的数据进行一些文件传输。

所以基本上，我有XML文件，内容如下：

<fftg>
<actions>
<!-- Rename file(s) -->
<rename>
<mandatory>0</mandatory>
<file name="foo" to="bar" />
</rename>
<!-- Transfer file(s) -->
<transfer>
<mandatory>0</mandatory>
<protocol>SFTP</protocol>
<server>fqdn</server>
<port>22</port>
<file name="bar" remotefolder="toto" />
</transfer>
<!-- Transfer file(s) -->
<transfer>
<mandatory>0</mandatory>
<protocol>SFTP</protocol>
<server>fqdn</server>
<port>22</port>
<file name="blabla" remotefolder="xxxx" />
<file name="blabla2" remotefolder="xxxx" />
</transfer>
</actions>
</fftg>

简而言之，我有一个执行"动作"的脚本。 每个动作可以重复X次。

现在，与其拥有一个带有一堆子例程等的重要脚本，我认为最好为我的应用程序创建模块，并将操作放在模块中。

例如：

FFTG::Rename
FFTG::Transfer
FFTG::Transfer::SFTP
FFTG::Transfer::FTP

等等(我已经创建了所有这些模块，它们独立工作正常)

并根据 XML 文件中指定的操作调用这些模块。 如果需要，人们可以创建新的模块/操作(我希望事情是模块化的)。

现在，我不知道如何正确地做到这一点。

所以我的问题是：请问最好的方法是什么？

目前，我的脚本正在读取这些操作：

# Load XML file
my $parser = XML::LibXML->new();
my $doc    = $parser->parse_file($FFTG_TSF . "/" . $tid . ".xml");
# Browse XML file
foreach my $transfer ($doc->findnodes('/fftg')) {
# Grab generic information
my($env) = $transfer->findnodes('./environment');
my($desc) = $transfer->findnodes('./description');
my($user) = $transfer->findnodes('./user');
print $env->to_literal, "n";
# Browse Actions
foreach my $action ($doc->findnodes('/fftg/actions/*')) {
my $actiontype = ucfirst($action->nodeName());
# how do i select a module from the $actiontype here ?     ($actiontype = Rename or Transfer)
# i can't do : use FFTG::$actiontype::execaction(); or something for example, it doesnt work
# and is it the right way of doing it ? 
}
}

但也许这不是正确的思维方式。(我正在使用Lib：：LibXML) 如何"动态"调用模块(例如使用名称中的变量，例如 FFTG：：$actiontype 而且，这是否意味着我必须在每个模块中都有相同的子例程？ 例 ： 子执行

因为我想向模块发送不同的数据......

有什么提示吗？ 再次感谢 问候

Answer 1

首先，您需要提供一个清晰的界面。每个模块都需要具有相同的结构。它是否是OOP并不重要，但它们都需要公开相同的接口。

下面是一个FFTG::Rename的非 OOp 实现示例。我省略了很多东西，但我认为很清楚发生了什么。

package FFTG::Rename;
use strict;
use warnings;
sub run {
my ($args) = @_;
if ($args->{mandatory}) {
# do stuff here
}
# checks args...
# do sanity checks...
return unless -f $args->{file}->{name}; # or whatever...
rename $args->{file}->{name}, $args->{file}->{to} or die $!;
return; # maybe return someting meaningful?
}

现在让我们假设我们有一堆这样的。我们如何加载它们？有几种方法可以做到这一点。我省略了将参数放入run函数的部分。您需要从XML中获取内容，并以与所有这些函数相同的方式传递它，但我认为这与该问题无关。

加载所有这些

最明显的是手动将它们加载到脚本中。

#!/usr/bin/env perl
use strict;
use warnings;
use XML::LibXML;
# load FFTG modules
use FFTG::Rename;
# ...

加载它们后，您可以调用该函数。exist关键字很方便，因为它也可用于检查函数是否存在。

foreach my $action ( $doc->findnodes('/fftg/actions/*') ) {
my $actiontype = ucfirst( $action->nodeName );
no strict 'refs';
if ( exists &{"FFTG::${actiontype}::run"} ) {
&{"FFTG::${actiontype}::run"}->( $parsed_node_information );
} else {
# this module was not loaded
}
}

不幸的是，非OO方法需要no strict 'refs'，这并不漂亮。最好以面向对象的方式执行此操作。但我会坚持这个答案。

这种方式的明显缺点是您需要始终加载所有模块，并且每当创建新模块时，都需要添加它。这是最不复杂的方法，但也具有最高的维护。

使用查找表自动加载

另一种方法是使用自动加载和定义允许的操作的查找表。如果您希望程序仅按需加载模块，因为您知道在每次调用中不需要所有模块，但您还希望控制加载的内容，这是有道理的。

而不是加载所有这些，加载可以外包给模块：：运行时。

use Module::Runtime 'require_module';
use Try::Tiny;
my %modules = (
'rename' => 'FFTG::Rename',
# ...
);
foreach my $action ( $doc->findnodes('/fftg/actions/*') ) {
try {
no strict 'refs';
require_module $modules{$action};
&{"FFTG::${actiontype}::run"}->($parsed_node_information);
}
catch {
# something went wrong
# maybe the module does not exist or it's not listed in the lookup table
warn $_;
};
}

我还添加了 Try：：Tiny 来处理错误处理。它使您可以控制出现问题时该怎么做。

这种方法可以让你控制允许哪些操作，如果你偏执，这很好。但它仍然需要您维护脚本并将新模块添加到%modules查找表中。

动态信任和加载

第三种，也是最通用的方法是使用 Module：：Runtime 在没有查找表的情况下动态加载内容。

use Module::Runtime 'require_module';
use Try::Tiny;
foreach my $action ( $doc->findnodes('/fftg/actions/*') ) {
try {
my $actiontype = ucfirst($action->nodeName);
require_module "FFTG::${actiontype}";
no strict 'refs';
&{"FFTG::${actiontype}::run"}->($parsed_node_information);
}
catch {
# something went wrong
# the module does not exist
};
}

这维护最少，但更危险。您不知道传入的数据是什么，现在没有健全性检查。我想不出利用我头顶上这个的方法，但可能有。不过，现在不需要编辑脚本并使模块列表保持最新。

结论

我可能会选择第二种方法。它为您提供控制，并且仍然保持动态。我不会使用我使用的非 OOP 方法。

您可以将其保留为非 OOP，并且仍然通过使用->对象表示法调用类方法来摆脱no strict 'refs'。然后你的包看起来像这样。

package FFTG::Rename;
use strict;
use warnings;
sub run {
my (undef, $args) = @_;
# ...
}

undef是不要捕获$class(不是$self)，因为我们不需要它。或者也许我们这样做，用于伐木。这要看情况。但是有了这个，您基本上可以按如下方式调用查找表解决方案的类方法。

require_module $modules{$action};
$modules{$action}->run($parsed_node_information);

这显然更清晰，更可取。