在预言机的触发器中使用 :new 和 new 有什么区别

Question

例如，

我有这个触发器

CREATE OR REPLACE TRIGGER SAL_REDUCE
BEFORE UPDATE ON DRIVER --or insert--
FOR EACH ROW
BEGIN
IF(NEW.SAL < 1000) THEN
RAISE_APPLICATION_ERROR(-20001,'SALARY CANNOT BE REDUCED!!! PAY THEM MORE');
END IF;
END;
/

和这个触发器

CREATE OR REPLACE TRIGGER Salary_check
BEFORE INSERT OR UPDATE OF Sal, Job ON Emp99
FOR EACH ROW
DECLARE
Minsal NUMBER;
Maxsal NUMBER;
Salary_out_of_range   EXCEPTION;
BEGIN
/* Retrieve the minimum and maximum salary for the
employee's new job classification from the SALGRADE
table into MINSAL and MAXSAL: */
SELECT Minsal, Maxsal INTO Minsal, Maxsal FROM Salgrade
WHERE Job_classification = :new.Job;
IF (:new.Sal < Minsal OR :new.Sal > Maxsal) THEN
  RAISE Salary_out_of_range;
END IF;
EXCEPTION
WHEN Salary_out_of_range THEN
  Raise_application_error (-20300,
     'Salary '||TO_CHAR(:new.Sal)||' out of range for '
     ||'job classification '||:new.Job
     ||' for employee '||:new.Ename);
WHEN NO_DATA_FOUND THEN
  Raise_application_error(-20322,
     'Invalid Job Classification '
     ||:new.Job_classification);
END;
/

因此，在第二个示例中，您注意到我在标题上描述的 ：new 的用法，在第一个示例中，不带冒号的 new 用法。 这两者有什么区别？

谢谢！

Answer 1

第一个触发器在语法上不正确。正如尼古拉斯已经评论的那样，触发器体内需要:new。

唯一需要new.的地方是在触发器定义的WHEN子句中。例如：

CREATE OR REPLACE TRIGGER SAL_REDUCE
BEFORE UPDATE ON DRIVER --or insert--
FOR EACH ROW
WHEN (NEW.SAL > 100)
BEGIN
  IF(:NEW.SAL < 1000) THEN
    RAISE_APPLICATION_ERROR(-20001,'SALARY CANNOT BE REDUCED!!! PAY THEM MORE');
  END IF;
END;
/

在这个愚蠢的人为示例中，触发器仅在SAL超过 100 时触发。