匹配和更新2个xml中的属性

Question

我试图通过匹配两个xml中的属性来更新xml中属性的值。

xml1:

<?xml version="1.0" encoding="utf-8"?>
<Products>
    <Product>
        <List prodId="123456" sellId="">        
        </List>
    </Product>
</Products>

xml2:

<?xml version="1.0" encoding="utf-8"?>
<Products>
    <Product>
        <info prodId="123456" sellId="121">         
            <qnty>4</qnty>
        </info>
        <info prodId="23456" sellId="890">          
            <qnty>1</qnty>
        </info>
    </Product>
</Products>

我需要节点，在第二个xml prodId属性，并从该节点，我需要采取属性sellId="890"，并在第一个xml填充。

所需输出:

<?xml version="1.0" encoding="utf-8"?>
<Products>
    <Product>
        <List prodId="123456" sellId="890">        
        </List>
    </Product>
</Products>

这是我的xsl

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
  version="1.0">  
  <xsl:output method="xml" indent="yes"/>
  <xsl:param name="f1" select="'xml2.xml'"/>    
  <xsl:variable name="doc1" select="document($f1)"/>  
  <xsl:key name="k1" match="Products/Product/info" use="@prodId"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
    </xsl:template>
    <xsl:template match="Products/Product/List">
      <xsl:variable name="tprodId" select="@prodId"/>
      <xsl:for-each select="$doc1">
        <xsl:attribute name="sellId">
                 <xsl:value-of select="key('k1', $tprodId)/@sellId"/>
              </xsl:attribute>                  
      </xsl:for-each>      
  </xsl:template>

Answer 1

我建议你这样做:

<xsl:template match="List" >
    <xsl:copy>
        <xsl:apply-templates select="@*"/>
        <xsl:variable name="tprodId" select="@prodId"/>
        <xsl:for-each select="$doc1">
            <xsl:copy-of select="key('k1', $tprodId)/@sellId"/>                
        </xsl:for-each>
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>

或者，如果你愿意:

<xsl:template match="@sellId" >
    <xsl:variable name="tprodId" select="../@prodId"/>
    <xsl:for-each select="$doc1">
        <xsl:copy-of select="key('k1', $tprodId)/@sellId"/>                
    </xsl:for-each>         
</xsl:template>