计数备忘录中的特定文本(Delphi)

Question

我有一个备忘录，里面有很多行'mango'，我想计算它找到'mango'文本的次数。

var
  f, mango: Integer;
begin
  mango := 0;
  for f := 0 to m0.lines.Count - 1 do
  begin
    if AnsiContainsStr(m0.lines[f], 'mango') then
    begin
      mango := mango + 1;
      m0.lines.Add(IntToStr(mango));
    end
  end;
end;

但是结果，例如，如果它找到六个"mango"条目，那么结果将是这样的:

1
2
3
4
5
6

我怎么能只有结果6?

Answer 1

如果您只想在memo中显示总数，那么您需要这样做:

var
  f, mango: Integer;
begin
  mango := 0;
  for f := 0 to m0.lines.Count - 1 do
  begin
    if AnsiContainsStr(m0.lines[f], 'mango') then
    begin
      mango := mango + 1;
    end
  end;
  m0.lines.Add(IntToStr(mango));    // This line needs to be outside of your loop
end;

每次计数增加时，您都将计数添加到列表中。

如果你想要一个可重用的函数，你可以这样做:

function CountStringListTexts(const ASearchList: TStrings; const ASearchText: string): Integer;
var
  f: Integer;
begin
  Result := 0;
  for f := 0 to ASearchList.Count - 1 do
  begin
    if AnsiContainsStr(ASearchList[f], ASearchText) then
    begin
      Result := Result + 1;
    end
  end;
end;

你可以这样做:

m0.lines.Add(IntToStr(CountStringListTexts(m0.Lines, 'mango')));

也可以创建一个类帮助器:

type
  TSClassHelper = class helper for TStrings
    function CountMatchTexts(const ASearchText: string): Integer;
  end;
function TSClassHelper.CountMatchTexts(const ASearchText: string): Integer;
var
  f: Integer;
begin
  Result := 0;
  for f := 0 to Self.Count - 1 do
  begin
    if AnsiContainsStr(Self.Strings[f], ASearchText) then
    begin
      Result := Result + 1;
    end
  end;
end;

使用这个非常容易。你只需要:

m0.lines.Add(IntToStr(m0.Lines.CountMatchTexts('mango')));