plPl/SQL大容量绑定/更快的更新语句

Question

我在PL/SQL中使用Bulk Bind时遇到问题。基本上，我想要的是一个表（Component）根据Component_id和fieldname更新其字段值。所有这些都作为参数传入（varchar2_nested_table类型实际上是字符串数组，每个需要发生的更新语句有一个元素）。因此，例如，如果Component_id="Compid1"且fieldname="name"，则字段值应更新为"新组件名称"。

我在下面键入了与此有关的代码http://www.oracle.com/technetwork/issue-archive/o14tech-plsql-l2-091157.html。代码可以工作，但并不比为in参数中的每个元素执行更新的简单循环快。因此，如果参数有1000个元素，那么将执行1000个更新语句。我也意识到我没有使用BULK COLLECT INTO，但我认为我不需要它，因为我不需要从数据库中选择任何内容，只需要更新即可。

目前，1000次更新都需要4-5秒。我认为我使用批量绑定不正确，或者对主题有误解，因为在示例中，我可以发现人们在2秒内执行50000行等。根据我的理解，FORALL应该通过减少上下文切换的数量来提高性能。我尝试了另一种我在网上找到的方法，使用游标和批量绑定，但结果相同。也许我对业绩的期望太高了？从其他人的结果来看，我不这么认为。如有任何帮助，我们将不胜感激。

create or replace procedure BulkUpdate(sendSubject_in IN varchar2_nested_table_type,
fieldname_in IN varchar2_nested_table_type,fieldvalue_in IN   varchar2_nested_table_type) is

TYPE component_aat IS TABLE OF component.component_id%TYPE
  INDEX BY PLS_INTEGER;
TYPE fieldname_aat IS TABLE OF component.fieldname%TYPE
  INDEX BY PLS_INTEGER;
TYPE fieldvalue_aat IS TABLE OF component.fieldvalue%TYPE
  INDEX BY PLS_INTEGER;
fieldnames fieldname_aat;
fieldvalues fieldvalue_aat;
approved_components component_aat;

PROCEDURE partition_eligibility
IS
BEGIN
  FOR indx IN sendSubject_in.FIRST .. sendSubject_in.LAST
  LOOP
    approved_components(indx) := sendSubject_in(indx);
    fieldnames(indx):= fieldname_in(indx);
    fieldvalues(indx) := fieldvalue_in(indx);
  END LOOP;
END;

PROCEDURE update_components
IS
BEGIN
  FORALL indx IN approved_components.FIRST .. approved_components.LAST
    UPDATE Component
      SET Fieldvalue = fieldvalues(indx)
      WHERE Component_id = approved_components(indx)
      AND Fieldname = fieldnames(indx);
END;
BEGIN
  partition_eligibility;
  update_components;
END BulkUpdate;

Answer 1

还有其他事情发生，我怀疑您的单个更新每次都需要花费大量时间，可能是因为存在触发器或低效索引。（请注意，如果每条语句单独使用都很昂贵，那么使用批量更新不会节省很多时间，因为与实际工作相比，上下文切换可以忽略不计）。

这是我的测试设置：

CREATE TABLE Component (
  Component_id NUMBER,
  fieldname    VARCHAR2(100),
  Fieldvalue   VARCHAR2(100),
  CONSTRAINT component_pk PRIMARY KEY (component_id, fieldname)
);
-- insert 1 million rows
INSERT INTO component 
  (SELECT ROWNUM, to_char(MOD(ROWNUM, 100)), dbms_random.string('p', 10) 
     FROM dual 
   CONNECT BY LEVEL <= 1e6);
CREATE OR REPLACE TYPE varchar2_nested_table_type AS TABLE OF VARCHAR2(100);
/
SET SERVEROUTPUT ON SIZE UNLIMITED FORMAT WRAPPED
DECLARE
   l_id    varchar2_nested_table_type;
   l_names varchar2_nested_table_type;
   l_value varchar2_nested_table_type;
   l_time  NUMBER;
BEGIN
   SELECT rownum, to_char(MOD(rownum, 100)), dbms_random.STRING('p', 10) 
     BULK COLLECT INTO l_id, l_names, l_value
     FROM dual
   CONNECT BY LEVEL <= 100000;
   l_time := dbms_utility.get_time;
   BulkUpdate(l_id, l_names, l_value);
   dbms_output.put_line((dbms_utility.get_time - l_time) || ' cs elapsed.');
END;
/

在一台不起眼的测试机上，100000行在大约1.5秒内更新。逐行更新同一数据集大约需要4秒。

你能用新创建的表运行类似的脚本吗？