在字符串xslt中查找数字

Question

我需要能够找到元素中数字的最后一次出现。例如，

<DATA1>States45bx3.33</DATA1>
<DATA2>States45bx33</DATA2>

从这个字符串中，我想获得XSLT中的最后一个数值，即第一种情况下为3.33，第二种情况下是33

Answer 1

好的，这是XSLT1.0 中的一个解决方案

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <output>
            <xsl:for-each select="root/*">
                <xsl:element name="{name()}">
                    <xsl:call-template name="getEndNumber">
                        <xsl:with-param name="input" select="normalize-space(.)"/>
                        <xsl:with-param name="dotIncluded" select="true()"/>
                    </xsl:call-template>
                </xsl:element>
            </xsl:for-each>
        </output>
    </xsl:template>
    <xsl:template name="getEndNumber">
        <xsl:param name="input"/>
        <xsl:param name="dotIncluded"/>
        <xsl:variable name="len" select="string-length($input)"/>
        <xsl:choose>
            <xsl:when test="substring($input, $len, 1) &gt;= '0' and substring($input, $len, 1) &lt;= '9'">
                <xsl:call-template name="getEndNumber">
                    <xsl:with-param name="input" select="substring($input, 1, $len - 1)"/>
                    <xsl:with-param name="dotIncluded" select="$dotIncluded"/>
                </xsl:call-template>
                <xsl:value-of select="substring($input, $len, 1)"/>
            </xsl:when>
            <xsl:when test="substring($input, $len, 1) = '.' and $dotIncluded">
                <xsl:call-template name="getEndNumber">
                    <xsl:with-param name="input" select="substring($input, 1, $len - 1)"/>
                    <xsl:with-param name="dotIncluded" select="false()"/>
                </xsl:call-template>
                <xsl:value-of select="substring($input, $len, 1)"/>
            </xsl:when>
            <xsl:otherwise/>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

应用于

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <a>States45bx3.33</a>
    <b>States45bx33</b>
    <c>asdfs12310.13.0sads23.23</c>
    <d>asdfs12310.13.0sads23.23z</d>
    <e>asdfs12310.13.0sads23.23.34</e>
</root>

结果是

<?xml version="1.0" encoding="UTF-8"?>
<output>
    <a>3.33</a>
    <b>33</b>
    <c>23.23</c>
    <d/>
    <e>23.34</e>
</output>

Answer 2

如果您能够应用XSLT2.0，请使用以下内容：

<xsl:value-of select="replace(., '.*[^.d](d*.?d+)$', '$1')"/>

这将在当前节点的末尾返回一个数字，可以是整数，也可以是浮点值。

所用正则表达式的说明：
（1） .*=字符串开头的任意字符数
（2） [^.\d]=一个不是点也不是数字的字符
（3） （…）分组，允许引用回$1
（4） \d*。？\d+=可选数字+可选点+数字
（5） $=字符串结尾
（6） $1返回第1组

放入xslt:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <output>
            <xsl:for-each select="root/*">
                <num>
                    <xsl:value-of select="replace(., '.*[^.d](d*.?d+)$', '$1')"/>
                </num>
            </xsl:for-each>
        </output>
    </xsl:template>
</xsl:stylesheet>

应用于输入

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <number>States45bx3.33</number>
    <number>States45bx33</number>
    <number>asdfs12310.13.0sads23.23</number>
</root>

这导致

<?xml version="1.0" encoding="UTF-8"?>
<output>
    <num>3.33</num>
    <num>33</num>
    <num>23.23</num>
</output>

您可以将其放入xsl:function中（这也需要XSLT2.0），这样您就可以通过调用函数来简单地检索末尾的数字，并在函数之外完成围绕结果的元素：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
    version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:custom="http://customFunctions">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <output>
            <xsl:for-each select="root/*">
                <num>
                    <xsl:value-of select="custom:getNumberAtEnd(.)"/>
                </num>
            </xsl:for-each>
        </output>
    </xsl:template>
    <xsl:function name="custom:getNumberAtEnd">
        <xsl:param name="input"/>
        <xsl:value-of select="replace($input, '.*[^.d](d*.?d+)$', '$1')"/>
    </xsl:function>
</xsl:stylesheet>

备注：当字符串末尾没有数字时，函数调用或语句的早期xsl:value的结果将是整个输入字符串。当你不想这样做时，你必须首先测试字符串，或者当你确定字符串的末尾总是一个格式正确的数字时，你可以替换下面的正则表达式，它只返回最后一个非点、非数字后面的任何内容，这可能是一个空字符串。

<xsl:value-of select="replace($input, '.*[^.d](.*)$', '$1')"/>