通过 Nat-kind 重叠实例

Question

这个问题实际上是由于试图将几个数学组实现为类型而出现的。

循环群没有问题（Data.Group实例在别处定义）：

newtype Cyclic (n :: Nat) = Cyclic {cIndex :: Integer} deriving (Eq, Ord)
cyclic :: forall n. KnownNat n => Integer -> Cyclic n
cyclic x = Cyclic $ x `mod` toInteger (natVal (Proxy :: Proxy n))

但是对称群在定义某些实例（通过阶乘数系统实现）时存在一些问题：

infixr 6 :.
data Symmetric (n :: Nat) where
    S1 :: Symmetric 1
    (:.) :: (KnownNat n, 2 <= n) => Cyclic n -> Symmetric (n-1) -> Symmetric n
instance {-# OVERLAPPING #-} Enum (Symmetric 1) where
    toEnum _ = S1
    fromEnum S1 = 0
instance (KnownNat n, 2 <= n) => Enum (Symmetric n) where
    toEnum n = let
        (q,r) = divMod n (1 + fromEnum (maxBound :: Symmetric (n-1)))
        in toEnum q :. toEnum r
    fromEnum (x :. y) = fromInteger (cIndex x) * (1 + fromEnum (maxBound `asTypeOf` y)) + fromEnum y
instance {-# OVERLAPPING #-} Bounded (Symmetric 1) where
    minBound = S1
    maxBound = S1
instance (KnownNat n, 2 <= n) => Bounded (Symmetric n) where
    minBound = minBound :. minBound
    maxBound = maxBound :. maxBound

来自GHCI的错误消息（仅简短）：

Overlapping instances for Enum (Symmetric (n - 1))
Overlapping instances for Bounded (Symmetric (n - 1))

那么 GHC 如何知道 n-1 是否等于 1呢？我还想知道解决方案是否可以在没有FlexibleInstances的情况下编写.

Answer 1

添加Bounded (Symmetric (n-1))和Enum (Symmetric (n-1))作为约束，因为完全解决这些约束需要知道 n 的确切值。

instance (KnownNat n, 2 <= n, Bounded (Symmetric (n-1)), Enum (Symmetric (n-1))) =>
  Enum (Symmetric n) where
  ...
instance (KnownNat n, 2 <= n, Bounded (Symmetric (n-1))) =>
  Bounded (Symmetric n) where
  ...

---

为了避免FlexibleInstances（IMO不值得，FlexibleInstances是一个良性扩展），请使用Peano数字data Nat = Z | S Nat而不是GHC的原始表示。首先将实例头Bounded (Symmetric n)替换为Bounded (Symmetric (S (S n')))（这起着约束2 <= n的作用），然后用辅助类（可能更多）分解实例以满足实例头的标准要求。它可能看起来像这样：

instance Bounded_Symmetric n => Bounded (Symmetric n) where ...
instance Bounded_Symmetric O where ...
instance Bounded_Symmetric n => Bounded_Symmetric (S n) where ...