如何列出具有特定原子的所有谓词

另一种提问方式是:

如何列出原子的所有属性?

例如:

movie(agora).
director(agora, 'Alejandro Amenabar')
duration(agora, '2h').

所以，我想接收所有有agora作为参数的谓词。在这种情况下，它将是:movie, director, duration，以及其他参数('Alejandro Amenabar', '2h')。

我发现了:这个，还有这个问题，但是我不能很好地理解。

我想让变量answer的值为false如果PersonInvited不喜欢电影的某些部分

我的查询将是:

answer(Answer, PersonInvited, PersonWhoMadeInvitation, Movie)

答案:我不喜欢这个导演

answer(false, PersonInvited, PersonWhoMadeInvitation, Movie):-
    director(Movie, DirectorName),not(like(PersonInvited,DirectorName)).

同样的事情也会发生在任何类似于genre的属性上，例如

答案:我不喜欢这种类型

answer(false, PersonInvited, PersonWhoMadeInvitation, Movie):-
    genre(Movie, Genre), not(like(PersonInvited,Genre)).

所以，我想概括这种情况，而不是重复写每个对象的每个特征

我找到了两个解决方案，从我的角度来看，第二个更干净，但它们是不同的。

参数

PredName:谓词名。
Arity:谓词的Arity。
ParamValue:如果我想通过一个特定的参数过滤。
PosParam:参数在谓词中的位置。
ListParam:所有可能的值参数的值(必须一直是一个变量)。

解决方案1 :

filter_predicate(PredName, Arity, ParamValue,PosParam, ListParam):-
    current_predicate(PredName/Arity),
    Arity >= PosParam,
    nth(PosParam, ListParam, ParamValue),
    append([PredName], ListParam, PredList),
    GlobalArity is Arity + 1,
    length(PredList, GlobalArity),
    Predicate =.. PredList,
    Predicate.

查询

filter_predicate(PredName, Arity, agora, 1, Pm).

Arity = 2                                                                              
Pm = [agora,'Alejandro Amenabar']
PredName = director ? 
yes

Solution2 :

filter_predicate(PredName, Arity, ParamList):-
    current_predicate(PredName/Arity),
    append([PredName], ParamList, PredList), 
    GlobalArity is Arity + 1,
    length(PredList, GlobalArity),
    Predicate =.. PredList,
    Predicate.

查询1:

filter_predicate(PredName, Arity, [agora, X]).

Arity = 2
PredName = director
X = 'Alejandro Amenabar' ?

查询2:

filter_predicate(PredName, Arity, [X, 'Alejandro Amenabar']).

Arity = 2
PredName = director
X = agora ?

这是我的尝试，使用SWI-Prolog

?- current_predicate(so:F/N), N>0, length(As,N), Head =.. [F|As], clause(so:Head,Body), As=[A|_], A==agora.

注意，我编写了一个名为的模块，所以是事实，所以我用模块名限定了相关调用。这样的内置(clause/2和current_predicate/1)是ISO兼容的，而模块(在SWI-prolog中)则不是。所以我不确定可移植性，等等…

子句/2它是一个内置的，允许轻松编写元解释。请参阅链接，了解这个Prolog历史"优势点"的精彩介绍。

最后2个调用(我的意思是，As=[A|_], A==agora)避免匹配的子句有一个变量作为第一个参数。

使用prolog在列表中读取行

所有的谓词都在一个文件'my_file.pl'中。

。my_file.pl包含:

movie(agora).
director(agora, 'Alejandro Amenabar').
duration(agora, '2h').

你可以使用:

getLines(File,L):-
 setup_call_cleanup(
 open(File, read, In),
 readData(In, L),
 close(In)
 ).
readData(In, L):-
  read_term(In, H, []),
  (   H == end_of_file
  ->  L = []
  ;   L = [H|T],
      readData(In,T)
  ).

pred_arg_file(Pred,Argue,File):-
  getLines(File,L),
  member(M,L),
  M=..List,
  member(Argue,List),
  List=[Pred|_].

则可以查询:

 ?-pred_arg_file(Pred,agora,'my_file.pl').
 Pred = movie ;
 Pred = director ;
 Pred = duration ;
 false

或

?- findall(Pred,pred_arg_file(Pred,agora,'my_file.pl'),Preds).
Preds = [movie,director,duration].

如果你想返回属性，返回整个List，而不仅仅是头。

pred_arg_file(List,Argue,File):-
  getLines(File,L),
  member(M,L),
  M=..List,
  member(Argue,List).

根据我的理解，您应该更改数据表示，以便可以查询关系。正如其他答案所指出的那样，使用三元组，您可以轻松地编写代码将所有关系一次性更改为这种形式。然后，你需要找出储存喜欢或不喜欢的最佳方式。这将影响否定的工作方式。在这个例子中:

relation(starwars,is,movie).
relation(lucas, directs,starwars).
relation(agora, is,movie).
relation('Alejandro Amenabar', directs, agora).
relation(agora, duration, '2h').
like(ma,'Alejandro Amenabar').
like(ma,movie).
like(ma,'2h').
ma_does_not_want_to_go(Film):-
  relation(Film,is,movie),
  relation(Film,_,Test), +like(ma,Test).
ma_does_not_want_to_go(Film):-
  relation(Film,is,movie),
  relation(Test,_,Film), +like(ma,Test).
ma_wants_to_go(Film):-
  relation(Film,is,movie),
  +ma_does_not_want_to_go(Film).
sa_invites_ma(Film,true):-
  ma_wants_to_go(Film).
sa_invites_ma(Film,false):-
  ma_does_not_want_to_go(Film).

使用Logtalk和GNU Prolog作为后端编译器的解决方案草案:

% a movie protocol
:- protocol(movie).
    :- public([
        director/1,
        duration/1,
        genre/1
    ]).
:- end_protocol.

% a real movie
:- object('Agora',
    implements(movie)).
    director('Alejandro Amenabar').
    duration(120).
    genre(drama).
:- end_object.

% another real movie
:- object('The Terminator',
    implements(movie)).
    director('James Cameron').
    duration(112).
    genre(syfy).
:- end_object.

% a prototype person
:- object(person).
    :- public([
        likes_director/1,
        likes_genre/1
    ]).
    :- public(likes/1).
    likes(Movie) :-
        conforms_to_protocol(Movie, movie),
        (   Movie::genre(Genre),
            ::likes_genre(Genre) ->
            true
        ;   Movie::director(Director),
            ::likes_director(Director) ->
            true
        ;   fail
        ).
:- end_object.

% a real person
:- object(mauricio,
    extends(person)).
    likes_director('Ridlye Scott').
    likes_genre(drama).
    likes_genre(syfy).
:- end_object.

一些示例查询:

$ gplgt
...
| ?- {movies}.
...
(5 ms) yes
| ?- mauricio::likes('Agora').
true ? 
yes
| ?- mauricio::likes(Movie).  
Movie = 'Agora' ? ;
Movie = 'The Terminator' ? ;
no
| ?- 'The Terminator'::director(Director).
Director = 'James Cameron'
yes

代码可以通过几种方式进行改进，但这应该足以让您清楚地了解该解决方案。

如果我正确理解了你的问题，我建议如下:

如果你改变你的模式或者遵循这个想法，你可以创建一个方法来模拟同样的事情。

class(movie, agora).
property(director, agora, 'Alejandro Amenabar').
property(duration, agora, '2h').

如果您想要agora的类型，查询将是:

class(Type, agora)

如果你想要agora的所有属性，那将是:

property( PropertyName, agora, Value).

相关内容

最新更新

热门标签：