计算语句之间的距离

Question

是否可以在SPARQL或Jena中计算两个语句之间的距离？例如，是否可以计算以下两者之间的距离：

immanuel_kant dbprop:birthPlace Germany
John_Lock     dbprop:birthPlace England

Answer 1

很难确切地说出您要计算的内容(因为我们没有被告知(，但听起来您可以在SPARQL中执行此操作。 以下查询首先计算成对哲学家的相似性度量，并将其绑定到?initialSimilarity。 这只是他们名字长度的比率。 这不是一个特别好的相似性度量，但你说你已经定义了其中一些(评论中提到的.60(。 然后查询检索两位哲学家的出生地。 如果它们相同，则向相似性指标添加 .05，或者如果它们不同，则减去 .05，此值绑定到 ?finalSimilarity 。 (请注意，个人可能有多个 birthPlace 属性的值，因此您会看到同一对哲学家出现 n×m 次，其中 n 是一个拥有的出生地数，m 是另一个拥有的出生地数。您可以在此处按配对分组，然后取最终相似性的平均值，或者您可以做一些事情来解决多个陈述，例如，为每个陈述抽取一个代表性的出生地。

select ?name1 ?name2 ?bp1 ?bp2 ?initialSimilarity ?finalSimilarity where { 
  dbpedia-owl:Philosopher ^a ?phil1, ?phil2 .
  ?phil1 rdfs:label ?name1 .
  ?phil2 rdfs:label ?name2 .
  filter( langMatches(lang(?name1),"en") && langMatches(lang(?name2),"en"))
  bind ( strlen(?name1) as ?len1 )
  bind ( strlen(?name2) as ?len2 )
  bind ( if(?len1 < ?len2, ?len1, ?len2) as ?minLen )
  bind ( if(?len1 < ?len2, ?len2, ?len1) as ?maxLen )
  bind ( ?minLen/xsd:double(?maxLen) as ?initialSimilarity )
  ?phil1 dbpedia-owl:birthPlace ?bp1 .
  ?phil2 dbpedia-owl:birthPlace ?bp2 .
  bind ( if( ?bp1 = ?bp2, ?initialSimilarity + .05, ?initialSimilarity - .05) as ?finalSimilarity )
}
limit 10

SPARQL结果

根据评论中的澄清，计算初始相似性指标并不难，您将其定义为个人共有的类数与个人共有的类数。 这可以通过这样的查询来完成：

select ?philosopher1
       ?philosopher2
       (count(distinct ?commonType) as ?intersection)
       (count(distinct ?eitherType) as ?union)
       (count(distinct ?commonType)/xsd:double(count(distinct ?eitherType)) as ?similarity)
where {
  dbpedia-owl:Philosopher ^a ?philosopher1, ?philosopher2 .
  filter( ?philosopher1 != ?philosopher2 )
  ?commonType ^a ?philosopher1, ?philosopher2 .
  { ?eitherType ^a ?philosopher1 } UNION
  { ?eitherType ^a ?philosopher2 } 
}
group by ?philosopher1 ?philosopher2 
limit 3

SPARQL结果

产生这样的结果：

philosopher1                                  philosopher2                                    intersection  union similarity
http://dbpedia.org/resource/Bawa_Muhaiyaddeen http://dbpedia.org/resource/Abdolkarim_Soroush  6             34    0.176471
http://dbpedia.org/resource/Eric_Voegelin     http://dbpedia.org/resource/Abdolkarim_Soroush  6             30    0.2
http://dbpedia.org/resource/Eric_Ormsby       http://dbpedia.org/resource/%C3%89mile_Meyerson 18            24    0.75

您需要做的就是使用类似于第一个查询的查询来额外选择哲学家的出生地，然后执行您用于计算相似性的任何公式以获得相似性修饰符，然后您可以修改相似性值。