使用 XSLT 1.0 对 XML 数据重新编号和重新排序

Question

我需要仅使用 xslt 1.0 从 XML 文档中压缩缺失的数据，对其进行重新排序，以便项目的索引比任何缺少索引的索引大 1。（我承认，甚至很难用连贯的术语解释）。

我已经尝试了某些算法，但当然没有一种算法可以基于正在更改的输出来预测，并且不会连续迭代运行脚本，直到输出不再更改。一个过于简化的例子：

输入：

<Set Id="gump">
    <!--    Missing 2,3, must renumber 4->2 and 5->3    -->
    <parameter fieldId="primary.1.label" value="Was 1"/>
    <parameter fieldId="primary.4.label" value="Was 4"/>
    <parameter fieldId="primary.4.tag" value="Was 4"/>
    <parameter fieldId="primary.5.label" value="Was 5"/>
    <parameter fieldId="primary.5.somefld" value="Was 5"/>
</Set>

嵌入在 fieldId 属性中的索引必须按顺序输出，1， 2， 3;而不是 1， 4， 5，例如 - "primary.4.label" 在输出中必须是 "primary.2.label" 等。

在输入示例中，没有索引为 2 或 3 的项目。这是必须由索引大于缺失索引的后续项目填补的空白。所以所有的索引 4 都变成索引 2，所有的索引 5 都变成索引 3。

子字段（"标签"、"标签"、"somefld"）在索引集之间可能不同。有些可能存在于一组中，而在另一组中不存在。

输出：

<Set Id="gump">
    <!--    Desired output    -->
    <parameter fieldId="primary.1.label" value="Was 1"/>
    <parameter fieldId="primary.2.label" value="Was 4"/>
    <parameter fieldId="primary.2.tag" value="Was 4"/>
    <parameter fieldId="primary.3.label" value="Was 5"/>
    <parameter fieldId="primary.3.somefld" value="Was 5"/>
</Set>

我是 xslt 的新手，所以我一直在为钥匙等而苦苦挣扎。

Answer 1

---编辑---

显然，这是一个分组问题 - 在 XSLT 1.0 中最好使用 Muenchian 方法解决。

假设要替换的数字始终在给定字符串中的第一个和第二个句点之间，则可以应用以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:key name="param-by-id" match="parameter" use="substring-before(substring-after(@fieldId, '.'), '.')" />
<xsl:template match="Set">
    <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:for-each select="parameter[count(. | key('param-by-id', substring-before(substring-after(@fieldId, '.'), '.'))[1]) = 1]">
            <xsl:variable name="i" select="position()" />
            <xsl:for-each select="key('param-by-id', substring-before(substring-after(@fieldId, '.'), '.'))">
                <parameter>
                    <xsl:copy-of select="@*"/>
                    <xsl:attribute name="fieldId">
                        <xsl:value-of select="substring-before(@fieldId, '.')"/>
                        <xsl:text>.</xsl:text>
                        <xsl:value-of select="$i"/>
                        <xsl:text>.</xsl:text>
                        <xsl:value-of select="substring-after(substring-after(@fieldId, '.'), '.')"/>
                    </xsl:attribute>
                </parameter>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>

根据您的输入并接收：

<?xml version="1.0" encoding="UTF-8"?>
<Set Id="gump">
   <parameter fieldId="primary.1.label" value="Was 1"/>
   <parameter fieldId="primary.2.label" value="Was 4"/>
   <parameter fieldId="primary.2.tag" value="Was 4"/>
   <parameter fieldId="primary.3.label" value="Was 5"/>
   <parameter fieldId="primary.3.somefld" value="Was 5"/>
</Set>