在 Prolog 规则中使用事实列表

Question

我目前正在编写一个铁路线程序，但在使用来自事实的列表时遇到了一些麻烦。我对Prolog很陌生，到目前为止已经写了以下事实和规则：

location(euston, [northernLine]).
location(warrenStreet, [victoriaLine, northernLine]).
location(warwickAvenue, [bakerlooLine]).
location(paddington, [bakerlooLine]).
hasCommonLine(Location1, Location2, Line) :-
    location(Location1, Line),
    location(Location2, Line).

这个想法是让规则返回两个位置共有的行的名称。如果我尝试hasCommonLine(warwickAvenue,paddington,Line).，这有效，但是如果我尝试hasCommonLine(euston,warrenStreet,Line).，它会返回 false。

我怀疑这是因为该规则只检查列表的第一个元素，因此只比较[northernLine]和[victoriaLine]，而不是检查列表中的每个元素。任何完成此操作的指导将不胜感激！

Answer 1

您可以检查Line是否是两个列表的成员：

 hasCommonLine(Location1, Location2, Line) :-
     location(Location1, Lines1),
     location(Location2, Lines2),
     member(Line, Lines1),
     member(Line, Lines2).

然后，如果您需要找到两个位置之间所有共同的线路，您只需调用

 ?- findall(X, hasCommonLine(euston, warrenStreet, X), Y).
 Y = [northernLine].

Answer 2

我怀疑这是因为该规则仅检查列表的第一个元素。

否，程序会检查两个列表是否相同。因此，只有当两个Line完全等价（相同的元素，相同的顺序）时，它们才会匹配。

使用列表指定行列表是相当不合法的。通常，他们将其表示为事实列表，例如：

location_new(euston,northernLine).
location_new(warrenStreet,victoriaLine).
location_new(warrenStreet,northernLine).
location_new(warwickAvenue,bakerlooLine).
location_new(paddington,bakerlooLine).

所以这里warrenStreet发生两次：一次是victoriaLine，一次是northernLine。然后你可以简单地写：

hasCommonLine(Location1, Location2, Line) :-
    location_new(Location1, Line),
    location_new(Location2, Line).

然而，由于情况并非如此，您可以编写一个帮助器谓词location_helper/2：

location_helper(A,B) :-
    location(A,L),
    member(B,L).

然后定义：

hasCommonLine(Location1, Location2, Line) :-
    location_helper(Location1, Line),
    location_helper(Location2, Line).

Answer 3

您的规则需要改进。
现在，它会检查两个位置是否具有完全相同的行列表。

你应该做的是制定一个规则来检查两者之间是否存在重叠。您可以使用一个谓词来检查两个列表的交集。

它看起来像这样：

hasCommonLine(Location1,Location2, CommonLines):-
    location(Location1,Line1),
    location(Location2,Line2),
    intersection(Line1,Line2,CommonLines).