读取两个 YAML 文件并比较两个文件中显示的模块

Question

我正在尝试比较两个 YAML 文件，如下所示

• 忽略所有注释行

• 如果文件具有相同的模块，则比较这些模块的版本

• 如果版本不同，则将差异打印到文件output.log并引发错误

文件1.yml

Modules:
python:
PATH: /cfg/python/version-1.0
c:
PATH: /cfg/c/release-1.2.0
c++:
PATH: /cfg/c++/release-1.1.5
java:
PATH: /cfg/java/version-2.157
#connect:
#    PATH: /cfg/connect/release-1.2.3

文件2.yml

Modules:
python:
PATH: /cfg/python/version-1.1
c:
PATH: /cfg/c/release-1.2.0
java:
PATH: /cfg/java/version-2.161
eclipse:
PATH: /cfg/eclipse/version-4.5
#connect:
#    PATH: /cfg/connect/release-1.2.0

期望的输出

Error:
File1.yml - python: PATH: /cfg/python/verison-1.0
file2.yml - python: PATH: /cfg/python/verison-1.1
Error:
file1.yml - java: PATH: /cfg/java/version-2.157
file2.yml - java: PATH: /cfg/java/version-2.161

我的代码

use strict;
use warnings;
open f1, "file1.yml" or die "couldn't open the file: $! n ";
my @line1 = <f1>;
close(f1);
open f2, "file2.yml" or die "couldn't open the file: $! n ";
my @line2 = <f2>;
close(f2);
open( OUT, ">", "error.txt" );
for ( my $i = 0; $i < @line1; $i++ ) {
for ( my $j = 0; $j < @line2; $j++ ) {
if ( $line1[$i] =~ $line2[$j] ) {
print OUT "Match Found: n $line1[$i] n $line2[$j]";
}
}
}
close OUT;    

输出

Match Found:
Modules:
Modules:
Match Found:
python:
python:
Match Found:
c:
c: 
Match Found:
java:
java:
Match Found:
#connect:
#connect:

Answer 1

从技术上讲，您的程序没有任何问题，因此我不打算提供修复或解释。您编写的代码与您尝试解决的代码不同。

相反，我将逐步向您展示一种不同的方法。首先，请记住 YAML 是数据结构描述。你可以将其读入Perl并将其转换为Perl理解的本机数据结构，而不是使用文本比较。您的两个文件都具有相似的结构，这使得这非常简单。

读取数据结构并将其转换为其他格式是很困难的。幸运的是，Perl 的众多优势之一是很多问题已经解决，并且可以在 CPAN 上使用。

use strict;
use warnings;
use YAML 'LoadFile';
my $file1 = LoadFile('file1.yml');
my $file2 = LoadFile('file2.yml');

该程序将读取您的文件，并使用 YAML 模块中的LoadFile将内部的 YAML 数据结构转换为 Perl 哈希引用。

就其本身而言，这当然不是很有用。因此，让我们检查一下这些结构是什么样的。Data：:D umper 对此非常有用，它随您的 Perl 安装一起提供。(就我个人而言，我会使用 Data：:P rinter，因为我认为输出更具可读性，但这取决于您)。

use Data::Dumper;
print Dumper $file1;
print Dumper $file2;

这将向我们展示：

$VAR1 = {
'Modules' => {
'java' => {
'PATH' => '/cfg/java/version-2.157'
},
'c' => {
'PATH' => '/cfg/c/release-1.2.0'
},
'c++' => {
'PATH' => '/cfg/c++/release-1.1.5'
},
'python' => {
'PATH' => '/cfg/python/verison-1.0'
}
}
};
$VAR1 = {
'Modules' => {
'c' => {
'PATH' => '/cfg/c/release-1.2.0'
},
'java' => {
'PATH' => '/cfg/java/version-2.161'
},
'python' => {
'PATH' => '/cfg/python/verison-1.1'
},
'eclipse' => {
'PATH' => '/cfg/eclipse/version-4.5'
}
}
};

请注意，键在文件中的顺序不同。这是因为 Perl 中的哈希是无序的。这是一个功能。为了获得始终相同的输出，我们需要稍后sort这些键。

因此，我们看到两个结构都有一个关键模块。在里面，还有另一个哈希引用，它将语言作为键，在每个哈希引用中，还有另一个哈希引用，只有一个PATH键和一个值。我们对每种语言的每个PATH的价值感兴趣。

为了获取语言，我们迭代两个文件之一的模块keys。然后，我们可以一直向下比较这些值。如果它们不相等，我们将打印错误消息。

use v5.10; # to get say
# get shortcuts so the lines are not as long
my $modules1 = $file1->{Modules};
my $modules2 = $file2->{Modules};
foreach my $language (sort keys %{ $file1->{Modules} }) {
if ($modules1->{$language}->{PATH} ne $modules2->{$language}->{PATH} ) {
say "Error:";
say "file1.yml - $language: PATH: $modules1->{$language}->{PATH}";
say "file2.yml - $language: PATH: $modules2->{$language}->{PATH}";
}
}

我正在使用say而不是print，它在末尾为我们附加了一个换行符。$modules1和$modules2的其他变量只是为了使代码更易于阅读，因为$file1->{Modules}->{$language}->{PATH}很长。

现在，如果我们运行程序到这一点，我们将得到以下输出。

Error:
file1.yml - c++: PATH: /cfg/c++/release-1.1.5
file2.yml - c++: PATH: 
Error:
file1.yml - java: PATH: /cfg/java/version-2.157
file2.yml - java: PATH: /cfg/java/version-2.161
Error:
file1.yml - python: PATH: /cfg/python/verison-1.0
file2.yml - python: PATH: /cfg/python/verison-1.1
Use of uninitialized value in string ne at /home/simbabque/code/scratch/scratch.pl line 133.
Use of uninitialized value in concatenation (.) or string at /home/simbabque/code/scratch/scratch.pl line 136.

这几乎是我们想要的，但是有一些讨厌的警告(因为我们use warnings打开了)，并且c++没有价值。我们需要过滤掉仅存在于两个文件之一中的语言。

仅存在于file2.yml中的语言已经不被考虑，因为我们只查看file1.yml中的键。要从第一个文件中删除它们，我们必须在访问它们之前检查它们是否exist在另一个文件中。

next unless exists $modules2->{$language};

unless关键字就像if (not ...)，我认为它更容易阅读，尤其是在这种非常简洁的修复后符号中。现在程序给出预期的输出。

Error:
file1.yml - java: PATH: /cfg/java/version-2.157
file2.yml - java: PATH: /cfg/java/version-2.161
Error:
file1.yml - python: PATH: /cfg/python/verison-1.0
file2.yml - python: PATH: /cfg/python/verison-1.1

这是整个事情。不要忘记从代码中删除 Data：:D umper，因为它与生产程序无关。我们仅将其用作调试助手。

use strict;
use warnings;
use YAML 'LoadFile';
my $file1 = LoadFile('file1.yml');
my $file2 = LoadFile('file2.yml');
use v5.10;
# get shortcuts so the lines are not as long
my $modules1 = $file1->{Modules};
my $modules2 = $file2->{Modules};
foreach my $language (sort keys %{ $file1->{Modules} }) {
next unless exists $modules2->{$language};
if ($modules1->{$language}->{PATH} ne $modules2->{$language}->{PATH} ) {
say "Error:";
say "file1.yml - $language: PATH: $modules1->{$language}->{PATH}";
say "file2.yml - $language: PATH: $modules2->{$language}->{PATH}";
}
}