提取文件中出现第 n 个特殊字符之间的文本

Question

我正在尝试找出如何从XML中的节点中提取一些信息，其中信息位于答案中的第二个和第三个"|"之间...因为所包含的单词的长度可以变化，所以唯一常量是"|"

<root>
  <item>Apple|Pear|Orange|fig|Cherry|Banana</item>
</root>

我已经在这里看到了这个类似主题的示例，但它并不能完全回答在两个已知字符之间找到第 n 个字符的情况。

所以我想找到"橙色"作为我的答案，无论你在数组的其余部分将其他名称更改为什么。

Answer 1

1. 对于较低的 n 值（例如示例中的 3），可以使用：

   <xsl:value-of select="substring-before(substring-after(substring-after(item, '|'), '|'), '|')"/>
   

2. 对于较高的 n 值或预先未知的值，您将必须调用命名递归模板：

   <xsl:template name="get-Nth-value">
       <xsl:param name="list"/>
       <xsl:param name="N"/>
       <xsl:param name="delimiter" select="'|'"/>
       <xsl:choose>
           <xsl:when test="$N = 1">
               <xsl:value-of select="substring-before(concat($list, $delimiter), $delimiter)"/>
           </xsl:when>
           <xsl:when test="contains($list, $delimiter) and $N > 1">
               <!-- recursive call -->
               <xsl:call-template name="get-Nth-value">
                   <xsl:with-param name="list" select="substring-after($list, $delimiter)"/>
                   <xsl:with-param name="N" select="$N - 1"/>
                   <xsl:with-param name="delimiter" select="$delimiter"/>
               </xsl:call-template>
           </xsl:when>
       </xsl:choose>
   </xsl:template>
   

   调用示例：

   <xsl:template match="item">
       <xsl:copy>
           <xsl:call-template name="get-Nth-value">
               <xsl:with-param name="list" select="."/>
               <xsl:with-param name="N" select="3"/>
           </xsl:call-template>    
       </xsl:copy>
   </xsl:template>
   

3. 如果您的处理器支持它，您可以使用 EXSLT str:tokenize()扩展功能：

   <xsl:value-of select="str:tokenize(item, '|')[3]" />