如何将正确的库与 GLFW 链接为 cmake 中的外部项目

Question

我像这样包含glfw：

ExternalProject_Add(glfw-external
  URL https://github.com/glfw/glfw/releases/download/3.2.1/glfw-3.2.1.zip
  PREFIX ${CMAKE_CURRENT_BINARY_DIR}/glfw
  INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/install
  CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR>
)
add_dependencies(ShittyLife glfw-external)
if(UNIX)
  set(GLFW_LIB <What to put here?> libglfw3.a)
else()
  set(GLFW_LIB ${install_dir}/lib/glfw3.lib)
endif()

库稍后使用 GLFW_LIB 变量链接。

它在Windows上运行良好，但在Linux上我缺少一些库。glfw网页对此有解决方案，但似乎没有一个与ExternalProject_add兼容。

关于如何弄清楚所需的库是什么的任何想法，最好是以一种可以在不同机器/发行版上工作的方式？

如果有帮助，这是我在尝试构建时遇到的错误：

相关位：

/usr/bin/ld: /home/molion/Desktop/ShittyLife/build/install/lib/libglfw3.a(x11_window.c.o): undefined reference to symbol 'XConvertSelection'
//usr/lib/x86_64-linux-gnu/libX11.so.6: error adding symbols: DSO missing from command line

全部：

[ 94%] Building CXX object CMakeFiles/ShittyLife.dir/src/main.cpp.o
[100%] Linking CXX executable ShittyLife
/usr/bin/ld: /home/molion/Desktop/ShittyLife/build/install/lib/libglfw3.a(x11_window.c.o): undefined reference to symbol 'XConvertSelection'
//usr/lib/x86_64-linux-gnu/libX11.so.6: error adding symbols: DSO missing from command line
collect2: error: ld returned 1 exit status
CMakeFiles/ShittyLife.dir/build.make:95: recipe for target 'ShittyLife' failed
make[2]: *** [ShittyLife] Error 1
CMakeFiles/Makefile2:68: recipe for target 'CMakeFiles/ShittyLife.dir/all' failed
make[1]: *** [CMakeFiles/ShittyLife.dir/all] Error 2
Makefile:83: recipe for target 'all' failed
make: *** [all] Error 2

Answer 1

GLFW提供了一个CMake配置文件包，因此你应该使用find_package来查找它。

但是由于这仅在运行ExternalProject_Add后才可用，而不是在配置时可用，因此您必须创建一个超级项目并将您自己的项目也添加为 ExternalProject，如下所示：

ExternalProject_Add(glfw-test
    SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src
    PREFIX ${CMAKE_CURRENT_BINARY_DIR}
    INSTALL_COMMAND ""
    CMAKE_CACHE_ARGS "-DCMAKE_PREFIX_PATH:STRING=${GLFW_INSTALL_PREFIX}/lib/cmake"
    DEPENDS glfw-external
)

与set(GLFW_INSTALL_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/glfw_install")和GLFW_INSTALL_PREFIX也用于GLFW ExternalProject_Add。

然后，您可以使用

find_package(glfw3 REQUIRED)
find_package(OpenGL REQUIRED)

和

target_link_libraries(${PROJECT_NAME}
    glfw
    OpenGL::GL 
)

在您的项目中。

---

除了使用ExternalProject，您还可以遵循GLFW建议。

Answer 2

如果您愿意使用包管理器来处理依赖项，则可以考虑使用 Hunter 将 GLFW 添加到您的项目中。Hunter是用原生CMake编写的，并且已经在后台使用ExternalProject。但是，使用 imo 要容易得多。

有一个简短（和稀疏）的文档页面。基本上你的CMakeList.txt将看起来像下面这样......

# CMake version 3.0 or higher is required for the Hunter package manager.
cmake_minimum_required(VERSION 3.0)
# Include the Hunter package manager module.
include("cmake/HunterGate.cmake")
# Ensure a reproducible build by locking down the Hunter package versions.
HunterGate(
    URL "https://github.com/ruslo/hunter/archive/v0.19.77.tar.gz"
    SHA1 "8898dd07756c408c63c63add903c8600c4cf4c0e")
# Your project name here.
project(my_project_name)
# Tell Hunter which packages to pull in for our project.
hunter_add_package(glfw)
find_package(glfw3 REQUIRED)
# Link against your target.
target_link_libraries(my_target_name glfw)

魔术HunterGate系列可以在每个新的猎人版本中找到。我最近在Hunter上发布了一个代码广播，如果你迷路了，它可以帮助你完成这些步骤。

Answer 3

这是我使用

一段时间的CMakeLists.txt之一。 很简单，你告诉CMake glfw3的位置，这样它的CMake就可以完成它的工作，然后添加glfw作为链接库，并给它一个包含目录。这与在Visual Studio中包含GLFW没有太大区别。

cmake_minimum_required(VERSION 3.7)
project(SkyGames)
set(CMAKE_CXX_STANDARD 14)
set(SOURCE_FILES main.cpp)
add_executable(SkyGames ${SOURCE_FILES})
###########################
# GLFW
###########################
set(GLFW_BUILD_DOCS OFF CACHE BOOL "" FORCE)
set(GLFW_BUILD_TESTS OFF CACHE BOOL "" FORCE)
set(GLFW_BUILD_EXAMPLES OFF CACHE BOOL "" FORCE)
add_subdirectory(${PROJECT_SOURCE_DIR}/Externals/GLFW3)
target_link_libraries(SkyGames glfw)
include_directories(SkyGames ${GLFW_INCLUDE_DIR})
###########################
# GLEW
###########################
add_definitions(-DGLEW_STATIC)
set(GLEW_ROOT_DIR ${PROJECT_SOURCE_DIR}/Externals/glew2s)
set(GLEW_INCLUDE_DIR ${PROJECT_SOURCE_DIR}/Externals/glew2s/include)
set(GLEW_LIBRARY ${PROJECT_SOURCE_DIR}/Externals/glew2s/lib/Release/Win32/glew32s.lib)
find_package(GLEW REQUIRED)
include_directories(${GLEW_INCLUDE_DIR})
##########################
# OPENGL
##########################
find_package(OpenGL REQUIRED)
target_link_libraries(SkyGames ${GLEW_LIBRARY} ${OPENGL_LIBRARY} ${OPENGL_gl_LIBRARY} ${OPENGL_glu_LIBRARY})