在Smalltalk中与重复的组合

Question

我需要生成N个数字的所有可能组合，包括重复。

问题输入：我有 N 个单元格，我可以在每个单元格中输入一个 0 到 9 之间的数字。

错误的解决方案(N = 4(：

(0 to: 3) permutationsDo: [ : each | Transcript cr; show: each printString].

不包括 #(0 0 0 0( 、#(1 1 1 1( 、#(2 2 2 2( 等。

预期输出(N = 2，为简洁起见，范围为 1-4(：

#(1 1)
#(2 2)
#(3 3)
#(4 4)
#(2 1)
#(3 2)
#(4 3)
#(1 4)
#(3 1)
#(4 2)
#(1 3)
#(2 4)
#(4 1)
#(1 2)
#(2 3)
#(3 4)

Answer 1

这里有几个选择器，您可以使用它们来扩展SequenceableCollection。这是定义permutationsDo:并最终由Interval类继承的类。

类别"枚举"：

enumerationsDo: aBlock
   | anArray |
   anArray := Array new: self size.
   self enumerateWithSize: (self size) in: anArray do: [ :each | aBlock value: each ]

类别"私人"：

enumerateWithSize: aSize in: anArray do: aBlock
   (aSize = 1)
      ifTrue: [
         self do: [ :each |
            aBlock value: (anArray at: (self size - aSize + 1) put: each ; yourself) ] ]
      ifFalse: [
         self do: [ :each |
            self enumerateWithSize: (aSize - 1) in: anArray do: [ :eachArray |
               aBlock value: (eachArray at: (self size - aSize + 1) put: each ; yourself) ] ] ]

所以现在你可以做：

(0 to: 2) enumerationsDo: [ :each | Transcript show: each printString ; cr ]

这会产生：

#(0 0 0)
#(0 0 1)
#(0 0 2)
#(0 1 0)
#(0 1 1)
#(0 1 2)
#(0 2 0)
#(0 2 1)
#(0 2 2)
#(1 0 0)
#(1 0 1)
#(1 0 2)
#(1 1 0)
#(1 1 1)
#(1 1 2)
#(1 2 0)
#(1 2 1)
#(1 2 2)
#(2 0 0)
#(2 0 1)
#(2 0 2)
#(2 1 0)
#(2 1 1)
#(2 1 2)
#(2 2 0)
#(2 2 1)
#(2 2 2)

此选择器像现有的permutationsDo:选择器一样"对称"地运行，即结果数组中的元素数(选择数(与集合中的值数相同。

---

您可以轻松地从那里转到更通用的解决方案：

在"枚举"下：

enumerationsDo: aBlock
    self enumerationsOfSize: (self size) do: aBlock
enumerationsOfSize: aSize do: aBlock
   | anArray |
   anArray := Array new: aSize.
   self enumerateWithSize: aSize subSize: aSize in: anArray do: [ :each | aBlock value: each ]

在"私人"下：

enumerateWithSize: aSize subSize: sSize in: anArray do: aBlock
    (aSize < sSize)
        ifTrue: [ ^self error: 'subSize cannot exceed array size' ].
    (sSize < 1)
        ifTrue: [ ^self error: 'sizes must be positive' ].
    (sSize = 1)
        ifTrue: [
            self do: [ :each |
                aBlock value: (anArray at: (aSize - sSize + 1) put: each ; yourself) ] ]
        ifFalse: [
            self do: [ :each |
                self enumerateWithSize: aSize subSize: (sSize - 1) in: anArray do: [ :eachArray |
                    aBlock value: (eachArray at: (aSize - sSize + 1) put: each ; yourself) ] ] ]

下面是一个示例：

(1 to: 3) enumerationsOfSize: 2 do: [ :e | Transcript show: e printString ; cr ]

这会产生：

#(1 1)
#(1 2)
#(1 3)
#(2 1)
#(2 2)
#(2 3)
#(3 1)
#(3 2)
#(3 3)

Answer 2

为了简单起见，让我在SequenceableCollection中实现这一点：

nextCombination09
    | j |
    j := self findLast: [:ai | ai < 9] ifAbsent: [^nil].
    j + 1 to: self size do: [:i | self at: i put: 0].
    self at: j put: (self at: j) + 1

思路如下：使用词典顺序对所有组合进行排序。换句话说：

(a1, ..., an) < (b1, ..., bn)

如果ai = bi某些索引以下的所有i j aj < bj .

按照这个顺序，第一个组合是(0, ..., 0)，最后一个组合(9, ..., 9)。

此外，给定一个组合(a1, ..., an)按此顺序排列的下一个是将1添加到最低卓越指数的那个，这是最后一个索引j aj < 9。例如，(2, 3, 8, 9)旁边的是(2, 3, 9, 9)，因为两者之间不能有任何内容。

一旦我们到达(9, ..., 9)我们就完成了，并用nil回答。

请注意，上面的方法修改了接收器，这就是为什么我们必须在下面的脚本中copy。

这是生成所有组合的脚本(n是您N(

  n := <whatever>
  array := Array new: n withAll: 0.
  combinations := OrderedCollection new: (10 raisedTo: n).
  [
    combinations add: array copy.
    array nextCombination09 notNil] whileTrue.
  ^combinations

---

补遗

同样的技术可以用于其他类似性质的问题。