复制后更改属性值

Question

给定以下XML示例文件：

<root>
    <list number="123">
        <element>
            <name value="Name1"/>
            <line value="Line 1 :"/>
        </element>
        <element>
            <name value="Name1"/>
            <line value="Line 1 :"/>
        </element>
    </list>
</root>

我想创建一个 XSL 文件，允许我用 Line 1 : 123 替换每次出现的Line 1 :，123来自list节点的属性 number 。

我有以下 XSL 文件：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="element">
        <xsl:copy-of select="."/>
        <xsl:if test="@value='Line 1 :'">
            <xsl:attribute name="type">
                <xsl:value-of select="root/list[@number]"/>
            </xsl:attribute>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

但转换失败并返回类似"在添加文本、注释、pi 或子元素节点后，无法将属性和命名空间节点添加到父元素"的内容。

知道这个XSL有什么问题吗？

Answer 1

实际上

，您收到的错误消息：

添加

文本、注释、pi 或子元素节点后，无法将属性和命名空间节点添加到父元素

已经很好地解释了这个问题。您的模板匹配element如下所示

<xsl:template match="element">
    <xsl:copy-of select="."/>
    <xsl:if test="@value='Line 1 :'">
        <xsl:attribute name="type">

里面的第一条指令：

<xsl:copy-of select="."/>

复制 element 元素及其所有内容。这包括子元素、文本节点、属性等。

XSLT 的规则之一是，一旦将某些类型的节点添加到元素节点，就不能添加更多属性节点。但这正是您要做的

<xsl:attribute name="type">

构造属性节点。

您实际上不需要xsl:copy-of element 元素的全部内容，因为您有一个标识模板，默认情况下无论如何都会复制所有内容。

只干预您想要更改的确切位置。在这种情况下，它是 line 元素的 value 属性 - 因此请编写一个与此完全匹配的模板。

---

我认为您需要的是以下内容。如果没有，请显示您期望的 XML 输出，而不是描述它。我假设可能有多个具有不同number属性的list元素。

XSLT 样式表

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="element/line/@value">
        <xsl:attribute name="value">
            <xsl:value-of select="concat(., ' ', ../../../@number)"/>
        </xsl:attribute>
    </xsl:template>
</xsl:stylesheet>

XML 输出

<?xml version="1.0" encoding="utf-8"?>
<root>
   <list number="123">
      <element>
         <name value="Name1"/>
         <line value="Line 1 : 123"/>
      </element>
      <element>
         <name value="Name1"/>
         <line value="Line 1 : 123"/>
      </element>
   </list>
</root>

---

编辑

更简洁的要求是：给定任何 XML 文件，如何将任何等于"第 1 行："的属性值与上面数字中的 123 连接起来？我认为这需要多个模板...

不，这只是一个小的修改。将第二个模板更改为：

<xsl:template match="list//@*[. = 'Line 1 :']">
    <xsl:attribute name="{name()}">
        <xsl:value-of select="concat(., ' ', ancestor::list[1]/@number)"/>
    </xsl:attribute>
</xsl:template>