来自SQL ASP的电子邮件

Question

我有一个基于SQL数据库的Web门户，我们用来更新进度。在队列中更新记录后，Web表格应该发送电子邮件。

当前Web门户网站没有发送消息，我不确定故障点。该门户网站本身正在更新，因为我可以在SQL表中看到更新的记录。只是没有收到电子邮件。

更新04/27/18

所以我试图从新的途径中攻击它，这是在工作。

我所做的，将表格发送到使用PHP的外部网站，并将发送电子邮件。

我想知道如何通过变量？我一直在阅读指示一个小时，这对我来说没有任何意义。

本质上，我想从以下查询中传递一个变量

thequery = "SELECT loginemail FROM users WHERE referrerId = " & request.Form("referrerID")  & ""
objRS.open thequery, objConn, adOpenStatic, adLockReadOnly

，然后用类似的东西

将其传递

<form action="https://xxxxxx.com/hello.php?loginemail" method="post" name="updateclientform" id="updateclientform">

在php表单侧，根据变量"登录"

发送电子邮件

$to = trim(objRS("loginemail"));

有人帮忙吗？请

Answer 1

cdo可能不再需要MS支持 - 就像经典ASP本身一样，但仍然有效。我会研究在您的ASP应用程序中设置脚本，以使用CDO发送邮件。这样，您可以更好地控制任何SQL注入威胁并在一个地方管理整个过程。

这是一个示例CDO邮件脚本。

<%
'* Declare mailobject variables.
Dim validEmail, email_to, objCDOMail, objConf
Sub SetMailObject()
  '* set up CDO config
  Set objConf=Server.CreateObject("CDO.Configuration")
  objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
  objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mysmtp.server.com"
  objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
  objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "myusername"
  objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "mypassword"
  objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
  objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False
  objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
  objConf.Fields.Update
  ' Create an instance of the NewMail object.
  Set objCDOMail = Server.CreateObject("CDO.Message")
  Set objCDOMail.Configuration=objConf
End Sub
Sub sendLoginEmail(email_to)
  '* Call Sub to set mail object settings
  SetMailObject()
  '* Set the mail objects
  objCDOMail.From = "[e-mail]"
  objCDOMail.To = email_to
  objCDOMail.Bcc = ""
  objCDOMail.Subject = "My mail subject"
  objCDOMail.TextBody = "My email body"
  '* Send the message
  objCDOMail.Send
  '* Set the object to nothing
  Set objCDOMail = Nothing
End Sub
If Request("loginemail") <> "" Then
   validEmail = Request("loginemail")
   '* strongly suggest to perform some cleansing and validation of the email here
   Call sendLoginEmail(validEmail)
End If
%>