从 Smalltalk (Squeak) 中的字符串中提取子字符串

Question

>我正在尝试从字符串中提取子字符串，该子字符串将是 2 个分隔符之间的子字符串即它应该定义如下：

substring: aString delimiter: aDelimiter

举个例子，如果我得到这一行：

substring: 'dddd#sss#dddd' delimiter: '#'

该函数应返回"SSS"。

这是我一直在尝试的，但没有奏效：

substring: aString delimiter: aDelimiter
|index temp1 temp2 sz arr str|
      arr := aString asArray.
      sz := arr size.
      index := arr lastIndexOf: aDelimiter.
      temp1 := arr first: (sz - index +1).
      index := temp1 lastIndexOf: aDelimiter.
      sz :=temp1 size.
      temp2 := temp1 first: (sz - index).
      str := temp2 asString.
      ^str.

我不知道它是否值得一提，但它应该是一个类方法。

Answer 1

您的基本问题是参数 aDelimiter 是字符串而不是字符。 您希望使用 $# 而不是"#"来调用它。

现在来一些更简单的方法。可能最简单的方法是使用 subStrings： 方法：

('dddd#sss#dddd' subStrings: '#') at: 2

这样做的缺点是它将整个字符串提取为由#字符分隔的子字符串，这可能比您需要的要多。

下一个最简单的选择是使用流：

'dddd#sss#dddd' readStream upTo: $#; upTo: $#

该代码仅提取所需的部分。

Answer 2

正如David指出的那样，你离工作代码不远了。但我只想指出，这是非常程序化的。Smalltalk和OOP的很多魔力在于编写美观，易于理解的代码，将意图揭示消息发送到适当的对象社区。这包括依靠图像中已经存在的对象。我想不出什么时候我不得不为了这样的简单任务而达到如此低的水平。阅读许多很棒的 OOP 参考资料之一会很棒。我最喜欢的是关于Smallalk的指导课程

我认为大卫的解决方案是正确的。我个人喜欢second而不是at: 2，但这感觉很挑剔，可能是个人喜好('dddd#sss#dddd' subStrings: '#') second

Answer 3

虽然我喜欢上面的两个答案，但您可能还想考虑另一个更接近您最初尝试并且比其他答案更有效的答案，因为它只创建您正在寻找的对象（例如，没有中间流）

substringOf: aString delimitedBy: aCharacter
    | i j |
    i := aString indexOf: aCharacter.
    j := aString indexOf: aCharacter startingAt: i + 1.
    ^aString copyFrom: i + 1 to: j - 1

（请注意，我还建议使用稍微不同的选择器。

您要考虑的另一个方面是，如果aCharacter不在aString中，该方法应该如何反应，它只有一次或有三次或更多次出现。以下几行

：

substringOf: aString delimitedBy: aCharacter
    | i j |
    i := aString indexOf: aCharacter.
    i = 0 ifTrue: [^''].
    j := aString indexOf: aCharacter startingAt: i + 1.
    j = 0 ifTrue: [^''].
    ^aString copyFrom: i + 1 to: j - 1

但同样，如果性能在您的情况下不是问题，那么请选择 readStream upTo upTo 回答，因为它可能是最好的。