在空白分隔列表的元素上进行迭代

Question

我正试图找出使用XSL迭代空白分隔列表元素的最简单方法。假设我们有以下XML数据文件：

<?xml version="1.0" encoding="UTF-8"?>
<data>
    <!-- this list has 6 items -->
    <list>this is a list of strings</list>
</data>

list元素可以在XML模式中定义如下：

<xs:element name="list" type="strlist" />
<xs:simpleType name="strlist">
    <xs:list itemType="xs:string" />
</xs:simpleType>

我不确定XSL规范是否直接支持这种构造，但我认为应该支持，因为它在XMLSchema中是可用的。

如有任何帮助，我们将不胜感激。

Answer 1

XMLSchema早于XSLT2.0，因此XSLT2.0可以通过tokenize()来适应这一点。

XSLT1.0早于XMLSchema，因此您需要一个递归模板调用来分割字符串：

T:ftemp>type tokenize.xml
<?xml version="1.0" encoding="UTF-8"?>
<data>
    <!-- this list has 6 items -->
    <list>this is a list of strings</list>
</data>
T:ftemp>xslt tokenize.xml tokenize.xsl
this,is,a,list,of,strings
T:ftemp>type tokenize.xsl
<?xml version="1.0" encoding="US-ASCII"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">
<xsl:output method="text"/>
<xsl:template match="data">
  <xsl:call-template name="tokenize">
    <xsl:with-param name="string" select="normalize-space(list)"/>
  </xsl:call-template>
</xsl:template>
<xsl:template name="tokenize">
  <xsl:param name="string"/>
  <xsl:choose>
    <xsl:when test="contains($string,' ')">
      <xsl:value-of select="substring-before($string,' ')"/>
      <xsl:text>,</xsl:text>
      <xsl:call-template name="tokenize">
        <xsl:with-param name="string" select="substring-after($string,' ')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$string"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>
</xsl:stylesheet>
T:ftemp>xslt2 tokenize.xml tokenize2.xsl
this,is,a,list,of,strings
T:ftemp>type tokenize2.xsl
<?xml version="1.0" encoding="US-ASCII"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="2.0">
<xsl:output method="text"/>
<xsl:template match="data">
  <xsl:value-of select="tokenize(list,'s+')" separator=","/>
</xsl:template>
</xsl:stylesheet>
T:ftemp>

Answer 2

XSLT2.0确实直接支持这一点：在模式感知的转换中，您可以编写

<xsl:for-each select="data(list)">
  ...
</xsl:for-each>

如果元素"list"是在具有列表类型的模式中定义的，则这将遍历令牌。

但是你也可以通过编写在没有模式的情况下完成它

<xsl:for-each select="tokenize(list, 's+')">...</xsl:for-each>

在XSLT1.0中，您需要使用递归命名模板；您可以在www.exslt.org.